92 lines
2.4 KiB
Python
92 lines
2.4 KiB
Python
$input v_texcoord0
|
|
|
|
/*
|
|
* Copyright 2011-2016 Branimir Karadzic. All rights reserved.
|
|
* License: https://github.com/bkaradzic/bgfx#license-bsd-2-clause
|
|
*/
|
|
|
|
#include "../common/common.sh"
|
|
|
|
SAMPLER2D(s_normal, 0);
|
|
SAMPLER2D(s_depth, 1);
|
|
|
|
uniform vec4 u_lightPosRadius[1];
|
|
uniform vec4 u_lightRgbInnerR[1];
|
|
uniform mat4 u_mtx;
|
|
|
|
vec2 blinn(vec3 _lightDir, vec3 _normal, vec3 _viewDir)
|
|
{
|
|
float ndotl = dot(_normal, _lightDir);
|
|
vec3 reflected = _lightDir - 2.0*ndotl*_normal; // reflect(_lightDir, _normal);
|
|
float rdotv = dot(reflected, _viewDir);
|
|
return vec2(ndotl, rdotv);
|
|
}
|
|
|
|
float fresnel(float _ndotl, float _bias, float _pow)
|
|
{
|
|
float facing = (1.0 - _ndotl);
|
|
return max(_bias + (1.0 - _bias) * pow(facing, _pow), 0.0);
|
|
}
|
|
|
|
vec4 lit(float _ndotl, float _rdotv, float _m)
|
|
{
|
|
float diff = max(0.0, _ndotl);
|
|
float spec = step(0.0, _ndotl) * max(0.0, _rdotv * _m);
|
|
return vec4(1.0, diff, spec, 1.0);
|
|
}
|
|
|
|
vec4 powRgba(vec4 _rgba, float _pow)
|
|
{
|
|
vec4 result;
|
|
result.xyz = pow(_rgba.xyz, vec3_splat(_pow) );
|
|
result.w = _rgba.w;
|
|
return result;
|
|
}
|
|
|
|
vec3 calcLight(int _idx, vec3 _wpos, vec3 _normal, vec3 _view)
|
|
{
|
|
vec3 lp = u_lightPosRadius[_idx].xyz - _wpos;
|
|
float attn = 1.0 - smoothstep(u_lightRgbInnerR[_idx].w, 1.0, length(lp) / u_lightPosRadius[_idx].w);
|
|
vec3 lightDir = normalize(lp);
|
|
vec2 bln = blinn(lightDir, _normal, _view);
|
|
vec4 lc = lit(bln.x, bln.y, 1.0);
|
|
vec3 rgb = u_lightRgbInnerR[_idx].xyz * saturate(lc.y) * attn;
|
|
return rgb;
|
|
}
|
|
|
|
float toClipSpaceDepth(float _depthTextureZ)
|
|
{
|
|
#if BGFX_SHADER_LANGUAGE_HLSL || BGFX_SHADER_LANGUAGE_METAL
|
|
return _depthTextureZ;
|
|
#else
|
|
return _depthTextureZ * 2.0 - 1.0;
|
|
#endif // BGFX_SHADER_LANGUAGE_HLSL || BGFX_SHADER_LANGUAGE_METAL
|
|
}
|
|
|
|
vec3 clipToWorld(mat4 _invViewProj, vec3 _clipPos)
|
|
{
|
|
vec4 wpos = mul(_invViewProj, vec4(_clipPos, 1.0) );
|
|
return wpos.xyz / wpos.w;
|
|
}
|
|
|
|
void main()
|
|
{
|
|
vec3 normal = decodeNormalUint(texture2D(s_normal, v_texcoord0).xyz);
|
|
float deviceDepth = texture2D(s_depth, v_texcoord0).x;
|
|
float depth = toClipSpaceDepth(deviceDepth);
|
|
|
|
vec3 clip = vec3(v_texcoord0 * 2.0 - 1.0, depth);
|
|
#if BGFX_SHADER_LANGUAGE_HLSL || BGFX_SHADER_LANGUAGE_METAL
|
|
clip.y = -clip.y;
|
|
#endif // BGFX_SHADER_LANGUAGE_HLSL || BGFX_SHADER_LANGUAGE_METAL
|
|
vec3 wpos = clipToWorld(u_mtx, clip);
|
|
|
|
vec3 view = mul(u_view, vec4(wpos, 0.0) ).xyz;
|
|
view = -normalize(view);
|
|
|
|
vec3 lightColor;
|
|
lightColor = calcLight(0, wpos, normal, view);
|
|
gl_FragColor.xyz = toGamma(lightColor.xyz);
|
|
gl_FragColor.w = 1.0;
|
|
}
|