9a59303a4f
I have verified that the conversion here follows ITU-R BT.601 except for
the offsets 16/256 and 128/256 which should be 16/255 and 128/255
respectively.
I used to following octave script to verify this:
rf = 0.299;
gf = 0.587;
bf = 0.114;
crdiv = 1.402;
cbdiv = 1.772;
M = [ rf, gf, bf ;
-rf / cbdiv, -gf / cbdiv, (1 - bf) / cbdiv;
(1 - rf) / crdiv, -gf / crdiv, -bf / crdiv ];
YCbCr = [ 'Y'; 'Cb'; 'Cr' ];
RGB = [ 'R'; 'G'; 'B' ];
eq = [ ' '; '='; ' ' ];
l = [ ' [ '; ' [ '; ' [ ' ];
r = [ ' ] '; ' ] '; ' ] ' ];
mat = [
sprintf('%9f %9f %9f', M(1,:));
sprintf('%9f %9f %9f', M(2,:));
sprintf('%9f %9f %9f', M(3,:));
];
[ l YCbCr r eq l mat r l RGB r ]
R = inv(M);
mat = [
sprintf('%9f %9f %9f', R(1,:));
sprintf('%9f %9f %9f', R(2,:));
sprintf('%9f %9f %9f', R(3,:));
];
[ l RGB r eq l mat r l YCbCr r ]
[ R(:,1), R(:,2:3) .* (255/224) ]
The final matrix printed is what the shader uses down to +/- one digit,
so at least 7 correct decimals.
Signed-off-by: Pekka Paalanen <pekka.paalanen@collabora.com>
157 lines
4.1 KiB
GLSL
157 lines
4.1 KiB
GLSL
/*
|
|
* Copyright 2012 Intel Corporation
|
|
* Copyright 2015,2019,2021 Collabora, Ltd.
|
|
* Copyright 2016 NVIDIA Corporation
|
|
*
|
|
* Permission is hereby granted, free of charge, to any person obtaining
|
|
* a copy of this software and associated documentation files (the
|
|
* "Software"), to deal in the Software without restriction, including
|
|
* without limitation the rights to use, copy, modify, merge, publish,
|
|
* distribute, sublicense, and/or sell copies of the Software, and to
|
|
* permit persons to whom the Software is furnished to do so, subject to
|
|
* the following conditions:
|
|
*
|
|
* The above copyright notice and this permission notice (including the
|
|
* next paragraph) shall be included in all copies or substantial
|
|
* portions of the Software.
|
|
*
|
|
* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
|
|
* EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
|
|
* MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
|
|
* NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS
|
|
* BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN
|
|
* ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
|
|
* CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
|
|
* SOFTWARE.
|
|
*/
|
|
|
|
/* GLSL version 1.00 ES, defined in gl-shaders.c */
|
|
|
|
/*
|
|
* Enumeration of shader variants, must match enum gl_shader_texture_variant.
|
|
*/
|
|
#define SHADER_VARIANT_RGBX 1
|
|
#define SHADER_VARIANT_RGBA 2
|
|
#define SHADER_VARIANT_Y_U_V 3
|
|
#define SHADER_VARIANT_Y_UV 4
|
|
#define SHADER_VARIANT_Y_XUXV 5
|
|
#define SHADER_VARIANT_XYUV 6
|
|
#define SHADER_VARIANT_SOLID 7
|
|
#define SHADER_VARIANT_EXTERNAL 8
|
|
|
|
#if DEF_VARIANT == SHADER_VARIANT_EXTERNAL
|
|
#extension GL_OES_EGL_image_external : require
|
|
#endif
|
|
|
|
precision mediump float;
|
|
|
|
/*
|
|
* These undeclared identifiers will be #defined by a runtime generated code
|
|
* snippet.
|
|
*/
|
|
const int c_variant = DEF_VARIANT;
|
|
const bool c_green_tint = DEF_GREEN_TINT;
|
|
|
|
vec4
|
|
yuva2rgba(vec4 yuva)
|
|
{
|
|
vec4 color_out;
|
|
float Y, su, sv;
|
|
|
|
/* ITU-R BT.601 & BT.709 quantization (limited range) */
|
|
|
|
/* Y = 255/219 * (x - 16/256) */
|
|
Y = 1.16438356 * (yuva.x - 0.0625);
|
|
|
|
/* Remove offset 128/256, but the 255/224 multiplier comes later */
|
|
su = yuva.y - 0.5;
|
|
sv = yuva.z - 0.5;
|
|
|
|
/*
|
|
* ITU-R BT.601 encoding coefficients (inverse), with the
|
|
* 255/224 limited range multiplier already included in the
|
|
* factors for su (Cb) and sv (Cr).
|
|
*/
|
|
color_out.r = Y + 1.59602678 * sv;
|
|
color_out.g = Y - 0.39176229 * su - 0.81296764 * sv;
|
|
color_out.b = Y + 2.01723214 * su;
|
|
|
|
color_out.rgb *= yuva.w;
|
|
color_out.a = yuva.w;
|
|
|
|
return color_out;
|
|
}
|
|
|
|
#if DEF_VARIANT == SHADER_VARIANT_EXTERNAL
|
|
uniform samplerExternalOES tex;
|
|
#else
|
|
uniform sampler2D tex;
|
|
#endif
|
|
|
|
varying vec2 v_texcoord;
|
|
uniform sampler2D tex1;
|
|
uniform sampler2D tex2;
|
|
uniform float alpha;
|
|
uniform vec4 unicolor;
|
|
|
|
vec4
|
|
sample_input_texture()
|
|
{
|
|
vec4 yuva = vec4(0.0, 0.0, 0.0, 1.0);
|
|
|
|
/* Producing RGBA directly */
|
|
|
|
if (c_variant == SHADER_VARIANT_SOLID)
|
|
return unicolor;
|
|
|
|
if (c_variant == SHADER_VARIANT_RGBA ||
|
|
c_variant == SHADER_VARIANT_EXTERNAL) {
|
|
return texture2D(tex, v_texcoord);
|
|
}
|
|
|
|
if (c_variant == SHADER_VARIANT_RGBX)
|
|
return vec4(texture2D(tex, v_texcoord).rgb, 1.0);
|
|
|
|
/* Requires conversion to RGBA */
|
|
|
|
if (c_variant == SHADER_VARIANT_Y_U_V) {
|
|
yuva.x = texture2D(tex, v_texcoord).x;
|
|
yuva.y = texture2D(tex1, v_texcoord).x;
|
|
yuva.z = texture2D(tex2, v_texcoord).x;
|
|
|
|
} else if (c_variant == SHADER_VARIANT_Y_UV) {
|
|
yuva.x = texture2D(tex, v_texcoord).x;
|
|
yuva.yz = texture2D(tex1, v_texcoord).rg;
|
|
|
|
} else if (c_variant == SHADER_VARIANT_Y_XUXV) {
|
|
yuva.x = texture2D(tex, v_texcoord).x;
|
|
yuva.yz = texture2D(tex1, v_texcoord).ga;
|
|
|
|
} else if (c_variant == SHADER_VARIANT_XYUV) {
|
|
yuva.xyz = texture2D(tex, v_texcoord).bgr;
|
|
|
|
} else {
|
|
/* Never reached, bad variant value. */
|
|
return vec4(1.0, 0.3, 1.0, 1.0);
|
|
}
|
|
|
|
return yuva2rgba(yuva);
|
|
}
|
|
|
|
void
|
|
main()
|
|
{
|
|
vec4 color;
|
|
|
|
/* Electrical (non-linear) RGBA values, pre-multiplied */
|
|
color = sample_input_texture();
|
|
|
|
/* View alpha (opacity) */
|
|
color *= alpha;
|
|
|
|
if (c_green_tint)
|
|
color = vec4(0.0, 0.3, 0.0, 0.2) + color * 0.8;
|
|
|
|
gl_FragColor = color;
|
|
}
|