adc1914a40
The migration qtest all the way up to this point used to work by sheer
luck relying on the contents of all pages from 1MiB to 100MiB to contain
the same one value in the first byte initially.
This easily breaks if we reduce the amount of RAM for the test instances
from 150MiB to e.g 110MiB since that makes SeaBIOS dirty some of the
pages starting at about 0x5dd2000 (~93 MiB) as it reuses those for the
HighMemory allocator since commit dc88f9b72df ("malloc: use large
ZoneHigh when there is enough memory").
This would result in the following errors:
12/60 qemu:qtest+qtest-x86_64 / qtest-x86_64/migration-test ERROR 2.74s killed by signal 6 SIGABRT
stderr:
Memory content inconsistency at 5dd2000 first_byte = cc last_byte = cb current = 9e hit_edge = 1
Memory content inconsistency at 5dd3000 first_byte = cc last_byte = cb current = 89 hit_edge = 1
Memory content inconsistency at 5dd4000 first_byte = cc last_byte = cb current = 23 hit_edge = 1
Memory content inconsistency at 5dd5000 first_byte = cc last_byte = cb current = 31 hit_edge = 1
Memory content inconsistency at 5dd6000 first_byte = cc last_byte = cb current = 70 hit_edge = 1
Memory content inconsistency at 5dd7000 first_byte = cc last_byte = cb current = ff hit_edge = 1
Memory content inconsistency at 5dd8000 first_byte = cc last_byte = cb current = 54 hit_edge = 1
Memory content inconsistency at 5dd9000 first_byte = cc last_byte = cb current = 64 hit_edge = 1
Memory content inconsistency at 5dda000 first_byte = cc last_byte = cb current = 1d hit_edge = 1
Memory content inconsistency at 5ddb000 first_byte = cc last_byte = cb current = 1a hit_edge = 1
and in another 26 pages**
ERROR:../tests/qtest/migration-test.c:300:check_guests_ram: assertion failed: (bad == 0)
Fix this by always zeroing the first byte of each page in the range so
that we get consistent results no matter the initial contents.
Fixes: ea0c6d6239 ("test: Postcopy")
Signed-off-by: Daniil Tatianin <d-tatianin@yandex-team.ru>
Reviewed-by: Peter Xu <peterx@redhat.com>
Reviewed-by: Vladimir Sementsov-Ogievskiy <vsementsov@yandex-team.ru>
Reviewed-by: Juan Quintela <quintela@redhat.com>
Signed-off-by: Juan Quintela <quintela@redhat.com>
Message-ID: <20230919102346.2117963-3-d-tatianin@yandex-team.ru>
102 lines
2.3 KiB
ArmAsm
102 lines
2.3 KiB
ArmAsm
# x86 bootblock used in migration test
|
|
# repeatedly increments the first byte of each page in a 100MB
|
|
# range.
|
|
# Outputs an initial 'A' on serial followed by repeated 'B's
|
|
#
|
|
# Copyright (c) 2016 Red Hat, Inc. and/or its affiliates
|
|
# This work is licensed under the terms of the GNU GPL, version 2 or later.
|
|
# See the COPYING file in the top-level directory.
|
|
#
|
|
# Author: dgilbert@redhat.com
|
|
|
|
|
|
.code16
|
|
.org 0x7c00
|
|
.file "fill.s"
|
|
.text
|
|
.globl start
|
|
.type start, @function
|
|
start: # at 0x7c00 ?
|
|
cli
|
|
lgdt gdtdesc
|
|
mov $1,%eax
|
|
mov %eax,%cr0 # Protected mode enable
|
|
data32 ljmp $8,$0x7c20
|
|
|
|
.org 0x7c20
|
|
.code32
|
|
# A20 enable - not sure I actually need this
|
|
inb $0x92,%al
|
|
or $2,%al
|
|
outb %al, $0x92
|
|
|
|
# set up DS for the whole of RAM (needed on KVM)
|
|
mov $16,%eax
|
|
mov %eax,%ds
|
|
|
|
# Start from 1MB
|
|
.set TEST_MEM_START, (1024*1024)
|
|
.set TEST_MEM_END, (100*1024*1024)
|
|
|
|
mov $65,%ax
|
|
mov $0x3f8,%dx
|
|
outb %al,%dx
|
|
|
|
# bl keeps a counter so we limit the output speed
|
|
mov $0, %bl
|
|
|
|
pre_zero:
|
|
mov $TEST_MEM_START,%eax
|
|
do_zero:
|
|
movb $0, (%eax)
|
|
add $4096,%eax
|
|
cmp $TEST_MEM_END,%eax
|
|
jl do_zero
|
|
|
|
mainloop:
|
|
mov $TEST_MEM_START,%eax
|
|
innerloop:
|
|
incb (%eax)
|
|
add $4096,%eax
|
|
cmp $TEST_MEM_END,%eax
|
|
jl innerloop
|
|
|
|
inc %bl
|
|
andb $0x3f,%bl
|
|
jnz mainloop
|
|
|
|
mov $66,%ax
|
|
mov $0x3f8,%dx
|
|
outb %al,%dx
|
|
|
|
jmp mainloop
|
|
|
|
# GDT magic from old (GPLv2) Grub startup.S
|
|
.p2align 2 /* force 4-byte alignment */
|
|
gdt:
|
|
.word 0, 0
|
|
.byte 0, 0, 0, 0
|
|
|
|
/* -- code segment --
|
|
* base = 0x00000000, limit = 0xFFFFF (4 KiB Granularity), present
|
|
* type = 32bit code execute/read, DPL = 0
|
|
*/
|
|
.word 0xFFFF, 0
|
|
.byte 0, 0x9A, 0xCF, 0
|
|
|
|
/* -- data segment --
|
|
* base = 0x00000000, limit 0xFFFFF (4 KiB Granularity), present
|
|
* type = 32 bit data read/write, DPL = 0
|
|
*/
|
|
.word 0xFFFF, 0
|
|
.byte 0, 0x92, 0xCF, 0
|
|
|
|
gdtdesc:
|
|
.word 0x27 /* limit */
|
|
.long gdt /* addr */
|
|
|
|
/* I'm a bootable disk */
|
|
.org 0x7dfe
|
|
.byte 0x55
|
|
.byte 0xAA
|