mirror of
git://git.sv.gnu.org/nano.git
synced 2024-12-28 05:09:49 +03:00
bd338658be
git-svn-id: svn://svn.savannah.gnu.org/nano/trunk/nano@1219 35c25a1d-7b9e-4130-9fde-d3aeb78583b8
540 lines
22 KiB
Plaintext
540 lines
22 KiB
Plaintext
# gettext.m4 serial 14 (gettext-0.11.2)
|
|
dnl Copyright (C) 1995-2002 Free Software Foundation, Inc.
|
|
dnl This file is free software, distributed under the terms of the GNU
|
|
dnl General Public License. As a special exception to the GNU General
|
|
dnl Public License, this file may be distributed as part of a program
|
|
dnl that contains a configuration script generated by Autoconf, under
|
|
dnl the same distribution terms as the rest of that program.
|
|
dnl
|
|
dnl This file can can be used in projects which are not available under
|
|
dnl the GNU General Public License or the GNU Library General Public
|
|
dnl License but which still want to provide support for the GNU gettext
|
|
dnl functionality.
|
|
dnl Please note that the actual code of the GNU gettext library is covered
|
|
dnl by the GNU Library General Public License, and the rest of the GNU
|
|
dnl gettext package package is covered by the GNU General Public License.
|
|
dnl They are *not* in the public domain.
|
|
|
|
dnl Authors:
|
|
dnl Ulrich Drepper <drepper@cygnus.com>, 1995-2000.
|
|
dnl Bruno Haible <haible@clisp.cons.org>, 2000-2002.
|
|
|
|
dnl Macro to add for using GNU gettext.
|
|
|
|
dnl Usage: AM_GNU_GETTEXT([INTLSYMBOL], [NEEDSYMBOL], [INTLDIR]).
|
|
dnl INTLSYMBOL can be one of 'external', 'no-libtool', 'use-libtool'. The
|
|
dnl default (if it is not specified or empty) is 'no-libtool'.
|
|
dnl INTLSYMBOL should be 'external' for packages with no intl directory,
|
|
dnl and 'no-libtool' or 'use-libtool' for packages with an intl directory.
|
|
dnl If INTLSYMBOL is 'use-libtool', then a libtool library
|
|
dnl $(top_builddir)/intl/libintl.la will be created (shared and/or static,
|
|
dnl depending on --{enable,disable}-{shared,static} and on the presence of
|
|
dnl AM-DISABLE-SHARED). If INTLSYMBOL is 'no-libtool', a static library
|
|
dnl $(top_builddir)/intl/libintl.a will be created.
|
|
dnl If NEEDSYMBOL is specified and is 'need-ngettext', then GNU gettext
|
|
dnl implementations (in libc or libintl) without the ngettext() function
|
|
dnl will be ignored.
|
|
dnl INTLDIR is used to find the intl libraries. If empty,
|
|
dnl the value `$(top_builddir)/intl/' is used.
|
|
dnl
|
|
dnl The result of the configuration is one of three cases:
|
|
dnl 1) GNU gettext, as included in the intl subdirectory, will be compiled
|
|
dnl and used.
|
|
dnl Catalog format: GNU --> install in $(datadir)
|
|
dnl Catalog extension: .mo after installation, .gmo in source tree
|
|
dnl 2) GNU gettext has been found in the system's C library.
|
|
dnl Catalog format: GNU --> install in $(datadir)
|
|
dnl Catalog extension: .mo after installation, .gmo in source tree
|
|
dnl 3) No internationalization, always use English msgid.
|
|
dnl Catalog format: none
|
|
dnl Catalog extension: none
|
|
dnl If INTLSYMBOL is 'external', only cases 2 and 3 can occur.
|
|
dnl The use of .gmo is historical (it was needed to avoid overwriting the
|
|
dnl GNU format catalogs when building on a platform with an X/Open gettext),
|
|
dnl but we keep it in order not to force irrelevant filename changes on the
|
|
dnl maintainers.
|
|
dnl
|
|
AC_DEFUN([AM_GNU_GETTEXT],
|
|
[
|
|
dnl Argument checking.
|
|
ifelse([$1], [], , [ifelse([$1], [external], , [ifelse([$1], [no-libtool], , [ifelse([$1], [use-libtool], ,
|
|
[errprint([ERROR: invalid first argument to AM_GNU_GETTEXT
|
|
])])])])])
|
|
ifelse([$2], [], , [ifelse([$2], [need-ngettext], ,
|
|
[errprint([ERROR: invalid second argument to AM_GNU_GETTEXT
|
|
])])])
|
|
define(gt_included_intl, ifelse([$1], [external], [no], [yes]))
|
|
define(gt_libtool_suffix_prefix, ifelse([$1], [use-libtool], [l], []))
|
|
|
|
AC_REQUIRE([AM_PO_SUBDIRS])dnl
|
|
ifelse(gt_included_intl, yes, [
|
|
AC_REQUIRE([AM_INTL_SUBDIR])dnl
|
|
])
|
|
|
|
dnl Prerequisites of AC_LIB_LINKFLAGS_BODY.
|
|
AC_REQUIRE([AC_LIB_PREPARE_PREFIX])
|
|
AC_REQUIRE([AC_LIB_RPATH])
|
|
|
|
AC_MSG_CHECKING([whether NLS is requested])
|
|
dnl Default is enabled NLS
|
|
AC_ARG_ENABLE(nls,
|
|
[ --disable-nls do not use Native Language Support],
|
|
USE_NLS=$enableval, USE_NLS=yes)
|
|
AC_MSG_RESULT($USE_NLS)
|
|
AC_SUBST(USE_NLS)
|
|
|
|
ifelse(gt_included_intl, yes, [
|
|
BUILD_INCLUDED_LIBINTL=no
|
|
USE_INCLUDED_LIBINTL=no
|
|
])
|
|
LIBINTL=
|
|
LTLIBINTL=
|
|
POSUB=
|
|
|
|
dnl If we use NLS figure out what method
|
|
if test "$USE_NLS" = "yes"; then
|
|
gt_use_preinstalled_gnugettext=no
|
|
ifelse(gt_included_intl, yes, [
|
|
AC_MSG_CHECKING([whether included gettext is requested])
|
|
AC_ARG_WITH(included-gettext,
|
|
[ --with-included-gettext use the GNU gettext library included here],
|
|
nls_cv_force_use_gnu_gettext=$withval,
|
|
nls_cv_force_use_gnu_gettext=no)
|
|
AC_MSG_RESULT($nls_cv_force_use_gnu_gettext)
|
|
|
|
nls_cv_use_gnu_gettext="$nls_cv_force_use_gnu_gettext"
|
|
if test "$nls_cv_force_use_gnu_gettext" != "yes"; then
|
|
])
|
|
dnl User does not insist on using GNU NLS library. Figure out what
|
|
dnl to use. If GNU gettext is available we use this. Else we have
|
|
dnl to fall back to GNU NLS library.
|
|
|
|
dnl Add a version number to the cache macros.
|
|
define([gt_api_version], ifelse([$2], [need-ngettext], 2, 1))
|
|
define([gt_cv_func_gnugettext_libc], [gt_cv_func_gnugettext]gt_api_version[_libc])
|
|
define([gt_cv_func_gnugettext_libintl], [gt_cv_func_gnugettext]gt_api_version[_libintl])
|
|
|
|
AC_CACHE_CHECK([for GNU gettext in libc], gt_cv_func_gnugettext_libc,
|
|
[AC_TRY_LINK([#include <libintl.h>
|
|
extern int _nl_msg_cat_cntr;
|
|
extern int *_nl_domain_bindings;],
|
|
[bindtextdomain ("", "");
|
|
return (int) gettext ("")]ifelse([$2], [need-ngettext], [ + (int) ngettext ("", "", 0)], [])[ + _nl_msg_cat_cntr + *_nl_domain_bindings],
|
|
gt_cv_func_gnugettext_libc=yes,
|
|
gt_cv_func_gnugettext_libc=no)])
|
|
|
|
if test "$gt_cv_func_gnugettext_libc" != "yes"; then
|
|
dnl Sometimes libintl requires libiconv, so first search for libiconv.
|
|
ifelse(gt_included_intl, yes, , [
|
|
AM_ICONV_LINK
|
|
])
|
|
dnl Search for libintl and define LIBINTL, LTLIBINTL and INCINTL
|
|
dnl accordingly. Don't use AC_LIB_LINKFLAGS_BODY([intl],[iconv])
|
|
dnl because that would add "-liconv" to LIBINTL and LTLIBINTL
|
|
dnl even if libiconv doesn't exist.
|
|
AC_LIB_LINKFLAGS_BODY([intl])
|
|
AC_CACHE_CHECK([for GNU gettext in libintl],
|
|
gt_cv_func_gnugettext_libintl,
|
|
[gt_save_CPPFLAGS="$CPPFLAGS"
|
|
CPPFLAGS="$CPPFLAGS $INCINTL"
|
|
gt_save_LIBS="$LIBS"
|
|
LIBS="$LIBS $LIBINTL"
|
|
dnl Now see whether libintl exists and does not depend on libiconv.
|
|
AC_TRY_LINK([#include <libintl.h>
|
|
extern int _nl_msg_cat_cntr;
|
|
extern
|
|
#ifdef __cplusplus
|
|
"C"
|
|
#endif
|
|
const char *_nl_expand_alias ();],
|
|
[bindtextdomain ("", "");
|
|
return (int) gettext ("")]ifelse([$2], [need-ngettext], [ + (int) ngettext ("", "", 0)], [])[ + _nl_msg_cat_cntr + *_nl_expand_alias (0)],
|
|
gt_cv_func_gnugettext_libintl=yes,
|
|
gt_cv_func_gnugettext_libintl=no)
|
|
dnl Now see whether libintl exists and depends on libiconv.
|
|
if test "$gt_cv_func_gnugettext_libintl" != yes && test -n "$LIBICONV"; then
|
|
LIBS="$LIBS $LIBICONV"
|
|
AC_TRY_LINK([#include <libintl.h>
|
|
extern int _nl_msg_cat_cntr;
|
|
extern
|
|
#ifdef __cplusplus
|
|
"C"
|
|
#endif
|
|
const char *_nl_expand_alias ();],
|
|
[bindtextdomain ("", "");
|
|
return (int) gettext ("")]ifelse([$2], [need-ngettext], [ + (int) ngettext ("", "", 0)], [])[ + _nl_msg_cat_cntr + *_nl_expand_alias (0)],
|
|
[LIBINTL="$LIBINTL $LIBICONV"
|
|
LTLIBINTL="$LTLIBINTL $LTLIBICONV"
|
|
gt_cv_func_gnugettext_libintl=yes
|
|
])
|
|
fi
|
|
CPPFLAGS="$gt_save_CPPFLAGS"
|
|
LIBS="$gt_save_LIBS"])
|
|
fi
|
|
|
|
dnl If an already present or preinstalled GNU gettext() is found,
|
|
dnl use it. But if this macro is used in GNU gettext, and GNU
|
|
dnl gettext is already preinstalled in libintl, we update this
|
|
dnl libintl. (Cf. the install rule in intl/Makefile.in.)
|
|
if test "$gt_cv_func_gnugettext_libc" = "yes" \
|
|
|| { test "$gt_cv_func_gnugettext_libintl" = "yes" \
|
|
&& test "$PACKAGE" != gettext; }; then
|
|
gt_use_preinstalled_gnugettext=yes
|
|
else
|
|
dnl Reset the values set by searching for libintl.
|
|
LIBINTL=
|
|
LTLIBINTL=
|
|
INCINTL=
|
|
fi
|
|
|
|
ifelse(gt_included_intl, yes, [
|
|
if test "$gt_use_preinstalled_gnugettext" != "yes"; then
|
|
dnl GNU gettext is not found in the C library.
|
|
dnl Fall back on included GNU gettext library.
|
|
nls_cv_use_gnu_gettext=yes
|
|
fi
|
|
fi
|
|
|
|
if test "$nls_cv_use_gnu_gettext" = "yes"; then
|
|
dnl Mark actions used to generate GNU NLS library.
|
|
INTLOBJS="\$(GETTOBJS)"
|
|
BUILD_INCLUDED_LIBINTL=yes
|
|
USE_INCLUDED_LIBINTL=yes
|
|
LIBINTL="ifelse([$3],[],\${top_builddir}/intl,[$3])/libintl.[]gt_libtool_suffix_prefix[]a $LIBICONV"
|
|
LTLIBINTL="ifelse([$3],[],\${top_builddir}/intl,[$3])/libintl.[]gt_libtool_suffix_prefix[]a $LTLIBICONV"
|
|
LIBS=`echo " $LIBS " | sed -e 's/ -lintl / /' -e 's/^ //' -e 's/ $//'`
|
|
fi
|
|
|
|
if test "$gt_use_preinstalled_gnugettext" = "yes" \
|
|
|| test "$nls_cv_use_gnu_gettext" = "yes"; then
|
|
dnl Mark actions to use GNU gettext tools.
|
|
CATOBJEXT=.gmo
|
|
fi
|
|
])
|
|
|
|
if test "$gt_use_preinstalled_gnugettext" = "yes" \
|
|
|| test "$nls_cv_use_gnu_gettext" = "yes"; then
|
|
AC_DEFINE(ENABLE_NLS, 1,
|
|
[Define to 1 if translation of program messages to the user's native language
|
|
is requested.])
|
|
else
|
|
USE_NLS=no
|
|
fi
|
|
fi
|
|
|
|
if test "$USE_NLS" = "yes"; then
|
|
|
|
if test "$gt_use_preinstalled_gnugettext" = "yes"; then
|
|
if test "$gt_cv_func_gnugettext_libintl" = "yes"; then
|
|
AC_MSG_CHECKING([how to link with libintl])
|
|
AC_MSG_RESULT([$LIBINTL])
|
|
AC_LIB_APPENDTOVAR([CPPFLAGS], [$INCINTL])
|
|
fi
|
|
|
|
dnl For backward compatibility. Some packages may be using this.
|
|
AC_DEFINE(HAVE_GETTEXT, 1,
|
|
[Define if the GNU gettext() function is already present or preinstalled.])
|
|
AC_DEFINE(HAVE_DCGETTEXT, 1,
|
|
[Define if the GNU dcgettext() function is already present or preinstalled.])
|
|
fi
|
|
|
|
dnl We need to process the po/ directory.
|
|
POSUB=po
|
|
fi
|
|
|
|
ifelse(gt_included_intl, yes, [
|
|
dnl If this is used in GNU gettext we have to set BUILD_INCLUDED_LIBINTL
|
|
dnl to 'yes' because some of the testsuite requires it.
|
|
if test "$PACKAGE" = gettext; then
|
|
BUILD_INCLUDED_LIBINTL=yes
|
|
fi
|
|
|
|
dnl Make all variables we use known to autoconf.
|
|
AC_SUBST(BUILD_INCLUDED_LIBINTL)
|
|
AC_SUBST(USE_INCLUDED_LIBINTL)
|
|
AC_SUBST(CATOBJEXT)
|
|
AC_SUBST(INTLOBJS)
|
|
|
|
dnl For backward compatibility. Some configure.ins may be using this.
|
|
nls_cv_header_intl=
|
|
nls_cv_header_libgt=
|
|
|
|
dnl For backward compatibility. Some Makefiles may be using this.
|
|
DATADIRNAME=share
|
|
AC_SUBST(DATADIRNAME)
|
|
|
|
dnl For backward compatibility. Some Makefiles may be using this.
|
|
INSTOBJEXT=.mo
|
|
AC_SUBST(INSTOBJEXT)
|
|
|
|
dnl For backward compatibility. Some Makefiles may be using this.
|
|
GENCAT=gencat
|
|
AC_SUBST(GENCAT)
|
|
|
|
dnl Enable libtool support if the surrounding package wishes it.
|
|
INTL_LIBTOOL_SUFFIX_PREFIX=gt_libtool_suffix_prefix
|
|
AC_SUBST(INTL_LIBTOOL_SUFFIX_PREFIX)
|
|
])
|
|
|
|
dnl For backward compatibility. Some Makefiles may be using this.
|
|
INTLLIBS="$LIBINTL"
|
|
AC_SUBST(INTLLIBS)
|
|
|
|
dnl Make all documented variables known to autoconf.
|
|
AC_SUBST(LIBINTL)
|
|
AC_SUBST(LTLIBINTL)
|
|
AC_SUBST(POSUB)
|
|
])
|
|
|
|
|
|
dnl Checks for all prerequisites of the po subdirectory,
|
|
dnl except for USE_NLS.
|
|
AC_DEFUN([AM_PO_SUBDIRS],
|
|
[
|
|
AC_REQUIRE([AC_PROG_MAKE_SET])dnl
|
|
AC_REQUIRE([AC_PROG_INSTALL])dnl
|
|
AC_REQUIRE([AM_MKINSTALLDIRS])dnl
|
|
|
|
dnl Perform the following tests also if --disable-nls has been given,
|
|
dnl because they are needed for "make dist" to work.
|
|
|
|
dnl Search for GNU msgfmt in the PATH.
|
|
dnl The first test excludes Solaris msgfmt and early GNU msgfmt versions.
|
|
dnl The second test excludes FreeBSD msgfmt.
|
|
AM_PATH_PROG_WITH_TEST(MSGFMT, msgfmt,
|
|
[$ac_dir/$ac_word --statistics /dev/null >/dev/null 2>&1 &&
|
|
(if $ac_dir/$ac_word --statistics /dev/null 2>&1 >/dev/null | grep usage >/dev/null; then exit 1; else exit 0; fi)],
|
|
:)
|
|
AC_PATH_PROG(GMSGFMT, gmsgfmt, $MSGFMT)
|
|
|
|
dnl Search for GNU xgettext 0.11 or newer in the PATH.
|
|
dnl The first test excludes Solaris xgettext and early GNU xgettext versions.
|
|
dnl The second test excludes FreeBSD xgettext.
|
|
AM_PATH_PROG_WITH_TEST(XGETTEXT, xgettext,
|
|
[$ac_dir/$ac_word --omit-header --copyright-holder= /dev/null >/dev/null 2>&1 &&
|
|
(if $ac_dir/$ac_word --omit-header --copyright-holder= /dev/null 2>&1 >/dev/null | grep usage >/dev/null; then exit 1; else exit 0; fi)],
|
|
:)
|
|
dnl Remove leftover from FreeBSD xgettext call.
|
|
rm -f messages.po
|
|
|
|
dnl Search for GNU msgmerge 0.11 or newer in the PATH.
|
|
AM_PATH_PROG_WITH_TEST(MSGMERGE, msgmerge,
|
|
[$ac_dir/$ac_word --update -q /dev/null /dev/null >/dev/null 2>&1], :)
|
|
|
|
dnl This could go away some day; the PATH_PROG_WITH_TEST already does it.
|
|
dnl Test whether we really found GNU msgfmt.
|
|
if test "$GMSGFMT" != ":"; then
|
|
dnl If it is no GNU msgfmt we define it as : so that the
|
|
dnl Makefiles still can work.
|
|
if $GMSGFMT --statistics /dev/null >/dev/null 2>&1 &&
|
|
(if $GMSGFMT --statistics /dev/null 2>&1 >/dev/null | grep usage >/dev/null; then exit 1; else exit 0; fi); then
|
|
: ;
|
|
else
|
|
GMSGFMT=`echo "$GMSGFMT" | sed -e 's,^.*/,,'`
|
|
AC_MSG_RESULT(
|
|
[found $GMSGFMT program is not GNU msgfmt; ignore it])
|
|
GMSGFMT=":"
|
|
fi
|
|
fi
|
|
|
|
dnl This could go away some day; the PATH_PROG_WITH_TEST already does it.
|
|
dnl Test whether we really found GNU xgettext.
|
|
if test "$XGETTEXT" != ":"; then
|
|
dnl If it is no GNU xgettext we define it as : so that the
|
|
dnl Makefiles still can work.
|
|
if $XGETTEXT --omit-header --copyright-holder= /dev/null >/dev/null 2>&1 &&
|
|
(if $XGETTEXT --omit-header --copyright-holder= /dev/null 2>&1 >/dev/null | grep usage >/dev/null; then exit 1; else exit 0; fi); then
|
|
: ;
|
|
else
|
|
AC_MSG_RESULT(
|
|
[found xgettext program is not GNU xgettext; ignore it])
|
|
XGETTEXT=":"
|
|
fi
|
|
dnl Remove leftover from FreeBSD xgettext call.
|
|
rm -f messages.po
|
|
fi
|
|
|
|
AC_OUTPUT_COMMANDS([
|
|
for ac_file in $CONFIG_FILES; do
|
|
# Support "outfile[:infile[:infile...]]"
|
|
case "$ac_file" in
|
|
*:*) ac_file=`echo "$ac_file"|sed 's%:.*%%'` ;;
|
|
esac
|
|
# PO directories have a Makefile.in generated from Makefile.in.in.
|
|
case "$ac_file" in */Makefile.in)
|
|
# Adjust a relative srcdir.
|
|
ac_dir=`echo "$ac_file"|sed 's%/[^/][^/]*$%%'`
|
|
ac_dir_suffix="/`echo "$ac_dir"|sed 's%^\./%%'`"
|
|
ac_dots=`echo "$ac_dir_suffix"|sed 's%/[^/]*%../%g'`
|
|
# In autoconf-2.13 it is called $ac_given_srcdir.
|
|
# In autoconf-2.50 it is called $srcdir.
|
|
test -n "$ac_given_srcdir" || ac_given_srcdir="$srcdir"
|
|
case "$ac_given_srcdir" in
|
|
.) top_srcdir=`echo $ac_dots|sed 's%/$%%'` ;;
|
|
/*) top_srcdir="$ac_given_srcdir" ;;
|
|
*) top_srcdir="$ac_dots$ac_given_srcdir" ;;
|
|
esac
|
|
if test -f "$ac_given_srcdir/$ac_dir/POTFILES.in"; then
|
|
rm -f "$ac_dir/POTFILES"
|
|
test -n "$as_me" && echo "$as_me: creating $ac_dir/POTFILES" || echo "creating $ac_dir/POTFILES"
|
|
cat "$ac_given_srcdir/$ac_dir/POTFILES.in" | sed -e "/^#/d" -e "/^[ ]*\$/d" -e "s,.*, $top_srcdir/& \\\\," | sed -e "\$s/\(.*\) \\\\/\1/" > "$ac_dir/POTFILES"
|
|
# ALL_LINGUAS, POFILES, GMOFILES, UPDATEPOFILES, DUMMYPOFILES depend
|
|
# on $ac_dir but don't depend on user-specified configuration
|
|
# parameters.
|
|
if test -f "$ac_given_srcdir/$ac_dir/LINGUAS"; then
|
|
# The LINGUAS file contains the set of available languages.
|
|
if test -n "$ALL_LINGUAS"; then
|
|
test -n "$as_me" && echo "$as_me: setting ALL_LINGUAS in configure.in is obsolete" || echo "setting ALL_LINGUAS in configure.in is obsolete"
|
|
fi
|
|
ALL_LINGUAS_=`sed -e "/^#/d" "$ac_given_srcdir/$ac_dir/LINGUAS"`
|
|
# Hide the ALL_LINGUAS assigment from automake.
|
|
eval 'ALL_LINGUAS''=$ALL_LINGUAS_'
|
|
fi
|
|
case "$ac_given_srcdir" in
|
|
.) srcdirpre= ;;
|
|
*) srcdirpre='$(srcdir)/' ;;
|
|
esac
|
|
POFILES=
|
|
GMOFILES=
|
|
UPDATEPOFILES=
|
|
DUMMYPOFILES=
|
|
for lang in $ALL_LINGUAS; do
|
|
POFILES="$POFILES $srcdirpre$lang.po"
|
|
GMOFILES="$GMOFILES $srcdirpre$lang.gmo"
|
|
UPDATEPOFILES="$UPDATEPOFILES $lang.po-update"
|
|
DUMMYPOFILES="$DUMMYPOFILES $lang.nop"
|
|
done
|
|
# CATALOGS depends on both $ac_dir and the user's LINGUAS
|
|
# environment variable.
|
|
INST_LINGUAS=
|
|
if test -n "$ALL_LINGUAS"; then
|
|
for presentlang in $ALL_LINGUAS; do
|
|
useit=no
|
|
if test "%UNSET%" != "$LINGUAS"; then
|
|
desiredlanguages="$LINGUAS"
|
|
else
|
|
desiredlanguages="$ALL_LINGUAS"
|
|
fi
|
|
for desiredlang in $desiredlanguages; do
|
|
# Use the presentlang catalog if desiredlang is
|
|
# a. equal to presentlang, or
|
|
# b. a variant of presentlang (because in this case,
|
|
# presentlang can be used as a fallback for messages
|
|
# which are not translated in the desiredlang catalog).
|
|
case "$desiredlang" in
|
|
"$presentlang"*) useit=yes;;
|
|
esac
|
|
done
|
|
if test $useit = yes; then
|
|
INST_LINGUAS="$INST_LINGUAS $presentlang"
|
|
fi
|
|
done
|
|
fi
|
|
CATALOGS=
|
|
if test -n "$INST_LINGUAS"; then
|
|
for lang in $INST_LINGUAS; do
|
|
CATALOGS="$CATALOGS $lang.gmo"
|
|
done
|
|
fi
|
|
test -n "$as_me" && echo "$as_me: creating $ac_dir/Makefile" || echo "creating $ac_dir/Makefile"
|
|
sed -e "/^POTFILES =/r $ac_dir/POTFILES" -e "/^# Makevars/r $ac_given_srcdir/$ac_dir/Makevars" -e "s|@POFILES@|$POFILES|g" -e "s|@GMOFILES@|$GMOFILES|g" -e "s|@UPDATEPOFILES@|$UPDATEPOFILES|g" -e "s|@DUMMYPOFILES@|$DUMMYPOFILES|g" -e "s|@CATALOGS@|$CATALOGS|g" "$ac_dir/Makefile.in" > "$ac_dir/Makefile"
|
|
for f in "$ac_given_srcdir/$ac_dir"/Rules-*; do
|
|
if test -f "$f"; then
|
|
case "$f" in
|
|
*.orig | *.bak | *~) ;;
|
|
*) cat "$f" >> "$ac_dir/Makefile" ;;
|
|
esac
|
|
fi
|
|
done
|
|
fi
|
|
;;
|
|
esac
|
|
done],
|
|
[# Capture the value of obsolete $ALL_LINGUAS because we need it to compute
|
|
# POFILES, GMOFILES, UPDATEPOFILES, DUMMYPOFILES, CATALOGS. But hide it
|
|
# from automake.
|
|
eval 'ALL_LINGUAS''="$ALL_LINGUAS"'
|
|
# Capture the value of LINGUAS because we need it to compute CATALOGS.
|
|
LINGUAS="${LINGUAS-%UNSET%}"
|
|
])
|
|
])
|
|
|
|
|
|
dnl Checks for all prerequisites of the intl subdirectory,
|
|
dnl except for INTL_LIBTOOL_SUFFIX_PREFIX (and possibly LIBTOOL), INTLOBJS,
|
|
dnl USE_INCLUDED_LIBINTL, BUILD_INCLUDED_LIBINTL.
|
|
AC_DEFUN([AM_INTL_SUBDIR],
|
|
[
|
|
AC_REQUIRE([AC_PROG_INSTALL])dnl
|
|
AC_REQUIRE([AM_MKINSTALLDIRS])dnl
|
|
AC_REQUIRE([AC_PROG_CC])dnl
|
|
AC_REQUIRE([AC_CANONICAL_HOST])dnl
|
|
AC_REQUIRE([AC_PROG_RANLIB])dnl
|
|
AC_REQUIRE([AC_ISC_POSIX])dnl
|
|
AC_REQUIRE([AC_HEADER_STDC])dnl
|
|
AC_REQUIRE([AC_C_CONST])dnl
|
|
AC_REQUIRE([AC_C_INLINE])dnl
|
|
AC_REQUIRE([AC_TYPE_OFF_T])dnl
|
|
AC_REQUIRE([AC_TYPE_SIZE_T])dnl
|
|
AC_REQUIRE([AC_FUNC_ALLOCA])dnl
|
|
AC_REQUIRE([AC_FUNC_MMAP])dnl
|
|
AC_REQUIRE([jm_GLIBC21])dnl
|
|
|
|
AC_CHECK_HEADERS([argz.h limits.h locale.h nl_types.h malloc.h stddef.h \
|
|
stdlib.h string.h unistd.h sys/param.h])
|
|
AC_CHECK_FUNCS([feof_unlocked fgets_unlocked getc_unlocked getcwd getegid \
|
|
geteuid getgid getuid mempcpy munmap putenv setenv setlocale stpcpy \
|
|
strcasecmp strdup strtoul tsearch __argz_count __argz_stringify __argz_next])
|
|
|
|
AM_ICONV
|
|
AM_LANGINFO_CODESET
|
|
AM_LC_MESSAGES
|
|
|
|
dnl intl/plural.c is generated from intl/plural.y. It requires bison,
|
|
dnl because plural.y uses bison specific features. It requires at least
|
|
dnl bison-1.26 because earlier versions generate a plural.c that doesn't
|
|
dnl compile.
|
|
dnl bison is only needed for the maintainer (who touches plural.y). But in
|
|
dnl order to avoid separate Makefiles or --enable-maintainer-mode, we put
|
|
dnl the rule in general Makefile. Now, some people carelessly touch the
|
|
dnl files or have a broken "make" program, hence the plural.c rule will
|
|
dnl sometimes fire. To avoid an error, defines BISON to ":" if it is not
|
|
dnl present or too old.
|
|
AC_CHECK_PROGS([INTLBISON], [bison])
|
|
if test -z "$INTLBISON"; then
|
|
ac_verc_fail=yes
|
|
else
|
|
dnl Found it, now check the version.
|
|
AC_MSG_CHECKING([version of bison])
|
|
changequote(<<,>>)dnl
|
|
ac_prog_version=`$INTLBISON --version 2>&1 | sed -n 's/^.*GNU Bison.* \([0-9]*\.[0-9.]*\).*$/\1/p'`
|
|
case $ac_prog_version in
|
|
'') ac_prog_version="v. ?.??, bad"; ac_verc_fail=yes;;
|
|
1.2[6-9]* | 1.[3-9][0-9]* | [2-9].*)
|
|
changequote([,])dnl
|
|
ac_prog_version="$ac_prog_version, ok"; ac_verc_fail=no;;
|
|
*) ac_prog_version="$ac_prog_version, bad"; ac_verc_fail=yes;;
|
|
esac
|
|
AC_MSG_RESULT([$ac_prog_version])
|
|
fi
|
|
if test $ac_verc_fail = yes; then
|
|
INTLBISON=:
|
|
fi
|
|
])
|
|
|
|
|
|
AC_DEFUN([AM_MKINSTALLDIRS],
|
|
[
|
|
dnl If the AC_CONFIG_AUX_DIR macro for autoconf is used we possibly
|
|
dnl find the mkinstalldirs script in another subdir but $(top_srcdir).
|
|
dnl Try to locate is.
|
|
MKINSTALLDIRS=
|
|
if test -n "$ac_aux_dir"; then
|
|
MKINSTALLDIRS="$ac_aux_dir/mkinstalldirs"
|
|
fi
|
|
if test -z "$MKINSTALLDIRS"; then
|
|
MKINSTALLDIRS="\$(top_srcdir)/mkinstalldirs"
|
|
fi
|
|
AC_SUBST(MKINSTALLDIRS)
|
|
])
|