mirror of
https://github.com/MidnightCommander/mc
synced 2024-12-22 20:36:50 +03:00
3d75fad259
Seemingly that at some point clang started accepting _any_ flags, whereas previously it would error out. These days, you can give it -Whamsandwich and it will succeed, while at the same time throwing an annoying warning. Add -Werror so that everything gets flagged and set accordingly. Bugzilla: https://bugs.freedesktop.org/show_bug.cgi?id=108082 Cc: Vinson Lee <vlee@freedesktop.org> Repored-by: Vinson Lee <vlee@freedesktop.org> Signed-off-by: Emil Velikov <emil.velikov@collabora.com> Reviewed-by: Dylan Baker <dylan@pnwbakers.com> Reviewed-by: Eric Engestrom <eric.engestrom@intel.com> Signed-off-by: Yury V. Zaytsev <yury@shurup.com> Signed-off-by: Andrew Borodin <aborodin@vmail.ru>
59 lines
2.2 KiB
Plaintext
59 lines
2.2 KiB
Plaintext
# ===========================================================================
|
|
# https://www.gnu.org/software/autoconf-archive/ax_check_compile_flag.html
|
|
# ===========================================================================
|
|
#
|
|
# SYNOPSIS
|
|
#
|
|
# AX_CHECK_COMPILE_FLAG(FLAG, [ACTION-SUCCESS], [ACTION-FAILURE], [EXTRA-FLAGS], [INPUT])
|
|
#
|
|
# DESCRIPTION
|
|
#
|
|
# Check whether the given FLAG works with the current language's compiler
|
|
# or gives an error. (Warnings, however, are ignored)
|
|
#
|
|
# ACTION-SUCCESS/ACTION-FAILURE are shell commands to execute on
|
|
# success/failure.
|
|
#
|
|
# If EXTRA-FLAGS is defined, it is added to the current language's default
|
|
# flags (e.g. CFLAGS) when the check is done. The check is thus made with
|
|
# the flags: "CFLAGS EXTRA-FLAGS FLAG". This can for example be used to
|
|
# force the compiler to issue an error when a bad flag is given.
|
|
#
|
|
# INPUT gives an alternative input source to AC_COMPILE_IFELSE.
|
|
#
|
|
# NOTE: Implementation based on AX_CFLAGS_GCC_OPTION. Please keep this
|
|
# macro in sync with AX_CHECK_{PREPROC,LINK}_FLAG.
|
|
#
|
|
# LICENSE
|
|
#
|
|
# Copyright (c) 2008 Guido U. Draheim <guidod@gmx.de>
|
|
# Copyright (c) 2011 Maarten Bosmans <mkbosmans@gmail.com>
|
|
#
|
|
# Copying and distribution of this file, with or without modification, are
|
|
# permitted in any medium without royalty provided the copyright notice
|
|
# and this notice are preserved. This file is offered as-is, without any
|
|
# warranty.
|
|
|
|
# Yury Zaytsev:
|
|
# Toggle Werror since at some point clang started treating unknown -W
|
|
# flags as warnings, succeeding with the build, yet issuing an annoying
|
|
# warning.
|
|
|
|
#serial 6
|
|
|
|
AC_DEFUN([AX_CHECK_COMPILE_FLAG],
|
|
[AC_PREREQ(2.64)dnl for _AC_LANG_PREFIX and AS_VAR_IF
|
|
AS_VAR_PUSHDEF([CACHEVAR],[ax_cv_check_[]_AC_LANG_ABBREV[]flags_$4_$1])dnl
|
|
AC_CACHE_CHECK([whether _AC_LANG compiler accepts $1], CACHEVAR, [
|
|
ax_check_save_flags=$[]_AC_LANG_PREFIX[]FLAGS
|
|
_AC_LANG_PREFIX[]FLAGS="$[]_AC_LANG_PREFIX[]FLAGS $4 $1 -Werror"
|
|
AC_COMPILE_IFELSE([m4_default([$5],[AC_LANG_PROGRAM()])],
|
|
[AS_VAR_SET(CACHEVAR,[yes])],
|
|
[AS_VAR_SET(CACHEVAR,[no])])
|
|
_AC_LANG_PREFIX[]FLAGS=$ax_check_save_flags])
|
|
AS_VAR_IF(CACHEVAR,yes,
|
|
[m4_default([$2], :)],
|
|
[m4_default([$3], :)])
|
|
AS_VAR_POPDEF([CACHEVAR])dnl
|
|
])dnl AX_CHECK_COMPILE_FLAGS
|