mirror of
https://github.com/MidnightCommander/mc
synced 2024-12-22 12:32:40 +03:00
0eae2cb8dc
Macros get from other projects keep their original names: gl_FSTYPENAME, AX_PATH_LIB_PCRE, etc. Macros initially writtem for MC have original names with prefix mc_: mc_VERSION, mc_CHECK_GLIB, etc Macros get from other projects and modified for MC keep their original names with prefix mc_: mc_cu_PREREQ_STAT_PROG, mc_AC_GET_FS_INFO. Signed-off-by: Andrew Borodin <aborodin@vmail.ru>
35 lines
1015 B
Plaintext
35 lines
1015 B
Plaintext
dnl mc_EXTFS_CHECKS
|
|
dnl Check for tools used in extfs scripts.
|
|
|
|
dnl FIXME: make this configurable
|
|
AC_DEFUN([mc_EXTFS_CHECKS], [
|
|
AC_PATH_PROG([ZIP], [zip], [/usr/bin/zip])
|
|
AC_PATH_PROG([UNZIP], [unzip], [/usr/bin/unzip])
|
|
AC_CACHE_CHECK([for zipinfo code in unzip], [mc_cv_have_zipinfo],
|
|
[mc_cv_have_zipinfo=no
|
|
if $UNZIP -Z </dev/null >/dev/null 2>&1; then
|
|
mc_cv_have_zipinfo=yes
|
|
fi])
|
|
if test x"$mc_cv_have_zipinfo" = xyes; then
|
|
HAVE_ZIPINFO=1
|
|
else
|
|
HAVE_ZIPINFO=0
|
|
fi
|
|
AC_SUBST([HAVE_ZIPINFO])
|
|
])
|
|
|
|
|
|
dnl Enable Extfs (classic)
|
|
AC_DEFUN([mc_VFS_EXTFS],
|
|
[
|
|
AC_ARG_ENABLE([vfs-extfs],
|
|
AS_HELP_STRING([--enable-vfs-extfs], [Support for extfs filesystem @<:@yes@:>@]))
|
|
if test "$enable_vfs" = "yes" -a x"$enable_vfs_extfs" != x"no"; then
|
|
mc_EXTFS_CHECKS
|
|
enable_vfs_extfs="yes"
|
|
mc_VFS_ADDNAME([extfs])
|
|
AC_DEFINE([ENABLE_VFS_EXTFS], [1], [Support for extfs])
|
|
fi
|
|
AM_CONDITIONAL(ENABLE_VFS_EXTFS, [test "$enable_vfs" = "yes" -a x"$enable_vfs_extfs" = x"yes"])
|
|
])
|