mirror of
https://github.com/limine-bootloader/limine
synced 2024-12-08 07:54:04 +03:00
e1f6ac8860
* Initial aarch64 port * Enable chainload on aarch64 No changes necessary since it's all UEFI anyway. * Add specification for Limine protocol for aarch64 * PROTOCOL: Specify state of information in DT /chosen node * common: Add spinup code for aarch64 * common: Port elf and term to aarch64 * common: Port vmm to aarch64 Also prepare to drop VMM_FLAG_PRESENT on x86. * protos: Port limine boot protocol to aarch64 Also drop VMM_FLAG_PRESENT since we never unmap pages anyway. * test: Add DTB request * PROTOCOL: Port SMP request to aarch64 * cpu: Add cache maintenance functions for aarch64 * protos/limine, sys: Port SMP to aarch64 Also move common asm macros into a header file. * test: Start up APs * vmm: Unify get_next_level and implement large page splitting * protos/limine: Map framebuffer using correct caching mode on AArch64 * CI: Fix GCC build for aarch64 * entry, menu: Replace uses of naked attribute with separate asm file GCC does not understand the naked attribute on aarch64, and didn't understand it for x86 in older versions.
97 lines
1.8 KiB
Plaintext
97 lines
1.8 KiB
Plaintext
OUTPUT_FORMAT(elf64-littleaarch64)
|
|
OUTPUT_ARCH(aarch64)
|
|
ENTRY(_start)
|
|
|
|
PHDRS
|
|
{
|
|
text PT_LOAD FLAGS((1 << 0) | (1 << 2)) ;
|
|
data PT_LOAD FLAGS((1 << 1) | (1 << 2)) ;
|
|
dynamic PT_DYNAMIC FLAGS((1 << 1) | (1 << 2)) ;
|
|
}
|
|
|
|
SECTIONS
|
|
{
|
|
. = 0;
|
|
__image_base = .;
|
|
__image_size = __image_end - __image_base;
|
|
|
|
.text : {
|
|
*(.pe_header)
|
|
. = ALIGN(0x1000);
|
|
|
|
*(.text .text.*)
|
|
. = ALIGN(0x1000);
|
|
} :text
|
|
|
|
__text_start = __image_base + 0x1000;
|
|
__text_size = SIZEOF(.text) - 0x1000;
|
|
__text_end = __text_start + __text_size;
|
|
|
|
.data.sbat : {
|
|
*(.data.sbat)
|
|
. = ALIGN(0x1000);
|
|
} :data
|
|
|
|
PROVIDE(__sbat_sizev = 1);
|
|
|
|
__sbat_start = __text_end;
|
|
__sbat_size = SIZEOF(.data.sbat);
|
|
__sbat_end = __sbat_start + __sbat_size;
|
|
|
|
.data.reloc : {
|
|
*(.data.reloc)
|
|
. = ALIGN(0x1000);
|
|
} :data
|
|
|
|
__reloc_start = __sbat_end;
|
|
__reloc_size = SIZEOF(.data.reloc);
|
|
__reloc_end = __reloc_start + __reloc_size;
|
|
|
|
.data : {
|
|
*(.rodata .rodata.*)
|
|
|
|
#ifdef LINKER_NOMAP
|
|
full_map = .;
|
|
#else
|
|
*(.full_map)
|
|
#endif
|
|
|
|
*(.no_unwind)
|
|
|
|
data_begin = .;
|
|
*(.data .data.*)
|
|
*(.bss .bss.*)
|
|
*(COMMON)
|
|
data_end = .;
|
|
} :data
|
|
|
|
.rela : {
|
|
*(.rela .rela.*)
|
|
} :data
|
|
|
|
.got : {
|
|
*(.got .got.*)
|
|
} :data
|
|
|
|
.dynamic : {
|
|
*(.dynamic)
|
|
. = ALIGN(0x1000);
|
|
} :data :dynamic
|
|
|
|
__data_start = __reloc_end;
|
|
__data_size = SIZEOF(.data) + SIZEOF(.rela) + SIZEOF(.got) + SIZEOF(.dynamic);
|
|
__data_end = __data_start + __data_size;
|
|
|
|
// for GNU-EFI crt0:
|
|
_data = __data_start;
|
|
_data_size = __data_size;
|
|
_edata = __data_end;
|
|
|
|
__image_end = __data_end;
|
|
|
|
/DISCARD/ : {
|
|
*(.eh_frame)
|
|
*(.note .note.*)
|
|
}
|
|
}
|