mirror of https://github.com/ncroxon/gnu-efi
121 lines
2.5 KiB
Plaintext
121 lines
2.5 KiB
Plaintext
OUTPUT_FORMAT("elf64-ia64-little")
|
|
OUTPUT_ARCH(ia64)
|
|
ENTRY(_start_plabel)
|
|
SECTIONS
|
|
{
|
|
. = 0;
|
|
ImageBase = .;
|
|
/* .hash and/or .gnu.hash MUST come first! */
|
|
.hash : { *(.hash) }
|
|
.gnu.hash : { *(.gnu.hash) }
|
|
.eh_frame : { *(.eh_frame) }
|
|
.eh_frame_hdr : { *(.eh_frame_hdr) }
|
|
.gcc_except_table : { *(.gcc_except_table*) }
|
|
. = ALIGN(4096);
|
|
.text :
|
|
{
|
|
_text = .;
|
|
*(.text)
|
|
*(.text.*)
|
|
*(.gnu.linkonce.t.*)
|
|
*(.plt)
|
|
. = ALIGN(16);
|
|
}
|
|
_etext = .;
|
|
_text_size = _etext - _text;
|
|
. = DATA_SEGMENT_ALIGN (CONSTANT (MAXPAGESIZE), CONSTANT (COMMONPAGESIZE));
|
|
__gp = ALIGN (8) + 0x200000;
|
|
.sdata :
|
|
{
|
|
_data = .;
|
|
*(.got.plt)
|
|
*(.got)
|
|
*(.srodata)
|
|
*(.sdata)
|
|
*(.sbss)
|
|
*(.scommon)
|
|
}
|
|
. = ALIGN(4096);
|
|
.data :
|
|
{
|
|
*(.rodata*)
|
|
*(.ctors)
|
|
*(.data*)
|
|
*(.gnu.linkonce.d*)
|
|
*(.plabel) /* data whose relocs we want to ignore */
|
|
|
|
/*
|
|
* Note that these aren't the using the GNU "CONSTRUCTOR" output section
|
|
* command, so they don't start with a size. Because of p2align and the
|
|
* end/END definitions, and the fact that they're mergeable, they can also
|
|
* have NULLs which aren't guaranteed to be at the end.
|
|
*/
|
|
. = ALIGN(16);
|
|
__init_array_start = .;
|
|
*(SORT(.init_array.*))
|
|
*(.init_array)
|
|
__init_array_end = .;
|
|
. = ALIGN(16);
|
|
__CTOR_LIST__ = .;
|
|
*(SORT(.ctors.*))
|
|
*(.ctors)
|
|
__CTOR_END__ = .;
|
|
. = ALIGN(16);
|
|
__DTOR_LIST__ = .;
|
|
*(SORT(.dtors.*))
|
|
*(.dtors)
|
|
__DTOR_END__ = .;
|
|
. = ALIGN(16);
|
|
__fini_array_start = .;
|
|
*(SORT(.fini_array.*))
|
|
*(.fini_array)
|
|
__fini_array_end = .;
|
|
|
|
/* the EFI loader doesn't seem to like a .bss section, so we stick
|
|
it all into .data: */
|
|
*(.dynbss)
|
|
*(.bss*)
|
|
*(COMMON)
|
|
}
|
|
.note.gnu.build-id : { *(.note.gnu.build-id) }
|
|
|
|
. = ALIGN(4096);
|
|
.dynamic : { *(.dynamic) }
|
|
. = ALIGN(4096);
|
|
.rela :
|
|
{
|
|
*(.rela.text*)
|
|
*(.rela.sdata*)
|
|
*(.rela.data*)
|
|
*(.rela.got)
|
|
*(.rela.dyn)
|
|
*(.rela.gnu.linkonce.d*)
|
|
*(.rela.stab)
|
|
*(.rela.init_array*)
|
|
*(.rela.fini_array*)
|
|
*(.rela.ctors*)
|
|
*(.rela.dtors*)
|
|
}
|
|
. = ALIGN(4096);
|
|
.rela.plt : { *(.rela.plt) }
|
|
_edata = .;
|
|
_data_size = _edata - _etext;
|
|
. = ALIGN(4096);
|
|
.reloc : /* This is the PECOFF .reloc section! */
|
|
{
|
|
KEEP (*(.reloc))
|
|
}
|
|
. = ALIGN(4096);
|
|
.dynsym : { *(.dynsym) }
|
|
. = ALIGN(4096);
|
|
.dynstr : { *(.dynstr) }
|
|
. = DATA_SEGMENT_END (.);
|
|
/DISCARD/ :
|
|
{
|
|
*(.rela.plabel)
|
|
*(.rela.reloc)
|
|
*(.IA_64.unwind*)
|
|
*(.IA64.unwind*)
|
|
}
|
|
}
|