FreeRDP/libfreerdp/codec/CMakeLists.txt

# FreeRDP: A Remote Desktop Protocol Implementation
# libfreerdp-codec cmake build script
#
# Copyright 2012 Marc-Andre Moreau <marcandre.moreau@gmail.com>
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

set(MODULE_NAME "freerdp-codec")
set(MODULE_PREFIX "FREERDP_CODEC")

set(${MODULE_PREFIX}_SRCS
	dsp.c
	color.c
	audio.c
	planar.c
	planar.h
	progressive.c
	bitmap_decode.c
	bitmap_encode.c
	rfx_bitstream.h
	rfx_constants.h
	rfx_decode.c
	rfx_decode.h
	rfx_differential.c
	rfx_differential.h
	rfx_dwt.c
	rfx_dwt.h
	rfx_encode.c
	rfx_encode.h
	rfx_quantization.c
	rfx_quantization.h
	rfx_rlgr.c
	rfx_rlgr.h
	rfx_types.h
	rfx.c
	region.c	
	nsc.c
	nsc_encode.c
	nsc_encode.h
	nsc_types.h
	ncrush.c
	xcrush.c
	mppc.c
	zgfx.c
	clear.c
	jpeg.c
	h264.c)

set(${MODULE_PREFIX}_SSE2_SRCS
	rfx_sse2.c
	rfx_sse2.h
	nsc_sse2.c
	nsc_sse2.h)

set(${MODULE_PREFIX}_NEON_SRCS
	rfx_neon.c
	rfx_neon.h)

if(WITH_SSE2)
	set(${MODULE_PREFIX}_SRCS ${${MODULE_PREFIX}_SRCS} ${${MODULE_PREFIX}_SSE2_SRCS})

	if(CMAKE_COMPILER_IS_GNUCC)
		set_source_files_properties(${${MODULE_PREFIX}_SSE2_SRCS} PROPERTIES COMPILE_FLAGS "-msse2")
	endif()

	if(MSVC)
		set_source_files_properties(${${MODULE_PREFIX}_SSE2_SRCS} PROPERTIES COMPILE_FLAGS "/arch:SSE2")
	endif()
endif()

if(WITH_NEON)
	set(${MODULE_PREFIX}_SRCS ${${MODULE_PREFIX}_SRCS} ${${MODULE_PREFIX}_NEON_SRCS})
	set_source_files_properties(${${MODULE_PREFIX}_NEON_SRCS} PROPERTIES COMPILE_FLAGS "-mfpu=neon -mfloat-abi=${ARM_FP_ABI} -Wno-unused-variable")
endif()

if(WITH_JPEG)
	include_directories(${JPEG_INCLUDE_DIR})
	set(FREERDP_JPEG_LIBS ${JPEG_LIBRARIES})
endif()

if(WITH_OPENH264)
	add_definitions(-DWITH_OPENH264)
	include_directories(${OPENH264_INCLUDE_DIR})
	set(FREERDP_OPENH264_LIBS ${OPENH264_LIBRARIES})
endif()

if(WITH_LIBAVCODEC)
	add_definitions(-DWITH_LIBAVCODEC)
	find_library(LIBAVCODEC_LIB avcodec)
	find_library(LIBAVUTIL_LIB avutil)
	set(FREERDP_LIBAVCODEC_LIBS ${LIBAVCODEC_LIB} ${LIBAVUTIL_LIB})
endif()

if(WITH_LIBAVCODEC OR WITH_OPENH264)
	if(CMAKE_SIZEOF_VOID_P EQUAL 8)
		set(arch64 TRUE)
	else()
		set(arch64 FALSE)
	endif()

	if(WITH_H264_ASM)
		set(H264_ASM  H264_ASM_o)
		add_definitions(-DWITH_H264_ASM)
		add_custom_target(${H264_ASM})

		if(arch64)
			set(SRC ${CMAKE_CURRENT_SOURCE_DIR}/h264_x64.asm)
			set(OBJ ${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/${H264_ASM}.dir/h264_x64.asm.o)
			add_custom_command(TARGET ${H264_ASM}
				COMMAND nasm ARGS -f elf64 -o ${OBJ} ${SRC})
		else()
			set(SRC ${CMAKE_CURRENT_SOURCE_DIR}/h264_x32.asm)
			set(OBJ ${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/${H264_ASM}.dir/h264_x32.asm.o)
			add_custom_command(TARGET ${H264_ASM}
				COMMAND nasm ARGS -f elf32 -o ${OBJ} ${SRC})
		endif()

		set(FREERDP_OPENH264_LIBS ${OPENH264_LIBRARIES} ${OBJ})
	endif()

	if(WITH_H264_SSSE3)
		set(H264_ASM  H264_ASM_o)
		add_definitions(-DWITH_H264_SSSE3)
		add_custom_target(${H264_ASM})

		if(arch64)
			set(SRC ${CMAKE_CURRENT_SOURCE_DIR}/h264_ssse3_x64.asm)
			set(OBJ ${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/${H264_ASM}.dir/h264_ssse3_x64.asm.o)
			add_custom_command(TARGET ${H264_ASM}
				COMMAND nasm ARGS -f elf64 -o ${OBJ} ${SRC})
		else()
			set(SRC ${CMAKE_CURRENT_SOURCE_DIR}/h264_ssse3_x32.asm)
			set(OBJ ${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/${H264_ASM}.dir/h264_ssse3_x32.asm.o)
			add_custom_command(TARGET ${H264_ASM}
				COMMAND nasm ARGS -f elf32 -o ${OBJ} ${SRC})
		endif()

		set(FREERDP_OPENH264_LIBS ${OPENH264_LIBRARIES} ${OBJ})
	endif()
endif()

add_complex_library(MODULE ${MODULE_NAME} TYPE "OBJECT"
	MONOLITHIC ${MONOLITHIC_BUILD}
	SOURCES ${${MODULE_PREFIX}_SRCS}
	EXPORT)

if (WITH_LIBRARY_VERSIONING)
  set_target_properties(${MODULE_NAME} PROPERTIES VERSION ${FREERDP_VERSION} SOVERSION ${FREERDP_API_VERSION})
endif()
set_target_properties(${MODULE_NAME} PROPERTIES PREFIX "lib")

set(${MODULE_PREFIX}_LIBS
	${FREERDP_JPEG_LIBS}
	${FREERDP_OPENH264_LIBS}
	${FREERDP_LIBAVCODEC_LIBS})

set_complex_link_libraries(VARIABLE ${MODULE_PREFIX}_LIBS
	MONOLITHIC ${MONOLITHIC_BUILD} INTERNAL
	MODULE freerdp
	MODULES freerdp-primitives freerdp-utils)
	

set(${MODULE_PREFIX}_LIBS ${${MODULE_PREFIX}_LIBS} winpr)

if(MONOLITHIC_BUILD)
	set(FREERDP_LIBS ${FREERDP_LIBS} ${${MODULE_PREFIX}_LIBS} PARENT_SCOPE)
else()
	target_link_libraries(${MODULE_NAME} ${${MODULE_PREFIX}_LIBS})
	install(TARGETS ${MODULE_NAME} DESTINATION ${CMAKE_INSTALL_LIBDIR} EXPORT FreeRDPTargets)
endif()

if(WITH_H264_ASM OR WITH_H264_SSSE3)
	add_dependencies(${MODULE_NAME} ${H264_ASM})
endif()

set_property(TARGET ${MODULE_NAME} PROPERTY FOLDER "FreeRDP/libfreerdp")

if(BUILD_TESTING)
	add_subdirectory(test)
endif()