9274ee656e
* initial riscv64 port * enable Paging Mode feature for all architectures * riscv: add missing protocol docs * riscv: fix tests * docs: clarify `LIMINE_PAGING_MODE_DEFAULT` macro * build: fix whitespace in common/GNUmakefile * riscv: default to Sv48 paging when supported * vmm: make `VMM_MAX_LEVEL` 1-indexed * limine: do not call `reported_addr()` before finaling paging mode smp/riscv: do not overwrite the argument passed to APs * limine/riscv: update default paging mode in limine.h * test/riscv: pad OVMF.fd when downloading it
95 lines
1.8 KiB
Plaintext
95 lines
1.8 KiB
Plaintext
OUTPUT_FORMAT(elf64-littleriscv)
|
|
OUTPUT_ARCH(riscv)
|
|
ENTRY(_start)
|
|
|
|
PHDRS
|
|
{
|
|
text PT_LOAD FLAGS((1 << 0) | (1 << 2)) ;
|
|
data PT_LOAD FLAGS((1 << 1) | (1 << 2)) ;
|
|
dynamic PT_DYNAMIC FLAGS((1 << 1) | (1 << 2)) ;
|
|
}
|
|
|
|
SECTIONS
|
|
{
|
|
. = 0;
|
|
__image_base = .;
|
|
__image_size = __image_end - __image_base;
|
|
|
|
.text : {
|
|
*(.pe_header)
|
|
. = ALIGN(0x1000);
|
|
|
|
*(.text .text.*)
|
|
. = ALIGN(0x1000);
|
|
} :text
|
|
|
|
__text_start = __image_base + 0x1000;
|
|
__text_size = SIZEOF(.text) - 0x1000;
|
|
__text_end = __text_start + __text_size;
|
|
|
|
.data.sbat : {
|
|
*(.data.sbat)
|
|
. = ALIGN(0x1000);
|
|
} :data
|
|
|
|
PROVIDE(__sbat_sizev = 1);
|
|
|
|
__sbat_start = __text_end;
|
|
__sbat_size = SIZEOF(.data.sbat);
|
|
__sbat_end = __sbat_start + __sbat_size;
|
|
|
|
.data.reloc : {
|
|
*(.data.reloc)
|
|
. = ALIGN(0x1000);
|
|
} :data
|
|
|
|
__reloc_start = __sbat_end;
|
|
__reloc_size = SIZEOF(.data.reloc);
|
|
__reloc_end = __reloc_start + __reloc_size;
|
|
|
|
.data : {
|
|
*(.rodata .rodata.*)
|
|
|
|
#ifdef LINKER_NOMAP
|
|
full_map = .;
|
|
#else
|
|
*(.full_map)
|
|
#endif
|
|
|
|
*(.no_unwind)
|
|
|
|
data_begin = .;
|
|
*(.data .data.*)
|
|
*(.sdata .sdata.*)
|
|
__global_pointer$ = .;
|
|
*(.sbss .sbss.*)
|
|
*(.bss .bss.*)
|
|
*(COMMON)
|
|
data_end = .;
|
|
} :data
|
|
|
|
.rela : {
|
|
*(.rela .rela.*)
|
|
} :data
|
|
|
|
.got : {
|
|
*(.got .got.*)
|
|
} :data
|
|
|
|
.dynamic : {
|
|
*(.dynamic)
|
|
. = ALIGN(0x1000);
|
|
} :data :dynamic
|
|
|
|
__data_start = __reloc_end;
|
|
__data_size = SIZEOF(.data) + SIZEOF(.rela) + SIZEOF(.got) + SIZEOF(.dynamic);
|
|
__data_end = __data_start + __data_size;
|
|
|
|
__image_end = __data_end;
|
|
|
|
/DISCARD/ : {
|
|
*(.eh_frame)
|
|
*(.note .note.*)
|
|
}
|
|
}
|