added man pages from 5.3
added Jamfile for man2doc git-svn-id: file:///srv/svn/repos/haiku/haiku/trunk@12656 a95241bf-73f2-0310-859d-f6bbb57e9c96
This commit is contained in:
Jérôme Duval
parent
ddbbb2e76d
commit
57ce68cc52
|
|
@ -0,0 +1,93 @@
|
|||
SubDir OBOS_TOP src bin coreutils man ;
|
||||
|
||||
Man2Docs
|
||||
basename.1
|
||||
cat.1
|
||||
chgrp.1
|
||||
chmod.1
|
||||
chown.1
|
||||
chroot.1
|
||||
cksum.1
|
||||
comm.1
|
||||
cp.1
|
||||
csplit.1
|
||||
cut.1
|
||||
date.1
|
||||
dd.1
|
||||
df.1
|
||||
dir.1
|
||||
dircolors.1
|
||||
dirname.1
|
||||
du.1
|
||||
echo.1
|
||||
env.1
|
||||
expand.1
|
||||
expr.1
|
||||
factor.1
|
||||
false.1
|
||||
fmt.1
|
||||
fold.1
|
||||
groups.1
|
||||
head.1
|
||||
hostid.1
|
||||
hostname.1
|
||||
id.1
|
||||
install.1
|
||||
join.1
|
||||
kill.1
|
||||
link.1
|
||||
ln.1
|
||||
logname.1
|
||||
ls.1
|
||||
md5sum.1
|
||||
mkdir.1
|
||||
mkfifo.1
|
||||
mknod.1
|
||||
mv.1
|
||||
nice.1
|
||||
nl.1
|
||||
nohup.1
|
||||
od.1
|
||||
paste.1
|
||||
pathchk.1
|
||||
pinky.1
|
||||
pr.1
|
||||
printenv.1
|
||||
printf.1
|
||||
ptx.1
|
||||
pwd.1
|
||||
readlink.1
|
||||
rm.1
|
||||
rmdir.1
|
||||
seq.1
|
||||
sha1sum.1
|
||||
shred.1
|
||||
sleep.1
|
||||
sort.1
|
||||
split.1
|
||||
stat.1
|
||||
stty.1
|
||||
su.1
|
||||
sum.1
|
||||
sync.1
|
||||
tac.1
|
||||
tail.1
|
||||
tee.1
|
||||
test.1
|
||||
touch.1
|
||||
tr.1
|
||||
true.1
|
||||
tsort.1
|
||||
tty.1
|
||||
uname.1
|
||||
unexpand.1
|
||||
uniq.1
|
||||
unlink.1
|
||||
uptime.1
|
||||
users.1
|
||||
vdir.1
|
||||
wc.1
|
||||
who.1
|
||||
whoami.1
|
||||
yes.1
|
||||
;
|
||||
|
|
@ -0,0 +1,636 @@
|
|||
#!/usr/bin/perl -w
|
||||
|
||||
# Generate a short man page from --help and --version output.
|
||||
# Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
|
||||
# Free Software Foundation, Inc.
|
||||
|
||||
# This program is free software; you can redistribute it and/or modify
|
||||
# it under the terms of the GNU General Public License as published by
|
||||
# the Free Software Foundation; either version 2, or (at your option)
|
||||
# any later version.
|
||||
|
||||
# This program is distributed in the hope that it will be useful,
|
||||
# but WITHOUT ANY WARRANTY; without even the implied warranty of
|
||||
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
||||
# GNU General Public License for more details.
|
||||
|
||||
# You should have received a copy of the GNU General Public License
|
||||
# along with this program; if not, write to the Free Software Foundation,
|
||||
# Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
|
||||
|
||||
# Written by Brendan O'Dea <bod@debian.org>
|
||||
# Available from ftp://ftp.gnu.org/gnu/help2man/
|
||||
|
||||
use 5.005;
|
||||
use strict;
|
||||
use Getopt::Long;
|
||||
use Text::Tabs qw(expand);
|
||||
use POSIX qw(strftime setlocale LC_ALL);
|
||||
use locale;
|
||||
|
||||
my $this_program = 'help2man';
|
||||
my $this_version = '1.35';
|
||||
|
||||
my $have_gettext;
|
||||
BEGIN {
|
||||
eval {
|
||||
require Locale::gettext;
|
||||
Locale::gettext->import;
|
||||
$have_gettext = 1;
|
||||
};
|
||||
|
||||
unless ($have_gettext)
|
||||
{
|
||||
*gettext = sub { $_[0] };
|
||||
*textdomain = sub {};
|
||||
}
|
||||
}
|
||||
|
||||
sub _ { gettext @_ }
|
||||
sub N_ { $_[0] }
|
||||
|
||||
textdomain $this_program;
|
||||
{
|
||||
my ($user_locale) = grep defined && length,
|
||||
(map $ENV{$_}, qw(LANGUAGE LC_ALL LC_MESSAGES LANG)), 'C';
|
||||
|
||||
sub kark # die with message formatted in the invoking user's locale
|
||||
{
|
||||
setlocale LC_ALL, $user_locale;
|
||||
my $fmt = gettext shift;
|
||||
die +(sprintf $fmt, @_), "\n";
|
||||
}
|
||||
}
|
||||
|
||||
my $version_info = sprintf _(<<'EOT'), $this_program, $this_version;
|
||||
GNU %s %s
|
||||
|
||||
Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004 Free Software
|
||||
Foundation, Inc.
|
||||
This is free software; see the source for copying conditions. There is NO
|
||||
warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
|
||||
|
||||
Written by Brendan O'Dea <bod@debian.org>
|
||||
EOT
|
||||
|
||||
my $help_info = sprintf _(<<'EOT'), $this_program, $this_program;
|
||||
`%s' generates a man page out of `--help' and `--version' output.
|
||||
|
||||
Usage: %s [OPTION]... EXECUTABLE
|
||||
|
||||
-n, --name=STRING description for the NAME paragraph
|
||||
-s, --section=SECTION section number for manual page (1, 6, 8)
|
||||
-m, --manual=TEXT name of manual (User Commands, ...)
|
||||
-S, --source=TEXT source of program (FSF, Debian, ...)
|
||||
-L, --locale=STRING select locale (default "C")
|
||||
-i, --include=FILE include material from `FILE'
|
||||
-I, --opt-include=FILE include material from `FILE' if it exists
|
||||
-o, --output=FILE send output to `FILE'
|
||||
-p, --info-page=TEXT name of Texinfo manual
|
||||
-N, --no-info suppress pointer to Texinfo manual
|
||||
--help print this help, then exit
|
||||
--version print version number, then exit
|
||||
|
||||
EXECUTABLE should accept `--help' and `--version' options although
|
||||
alternatives may be specified using:
|
||||
|
||||
-h, --help-option=STRING help option string
|
||||
-v, --version-option=STRING version option string
|
||||
|
||||
Report bugs to <bug-help2man@gnu.org>.
|
||||
EOT
|
||||
|
||||
my $section = 1;
|
||||
my $manual = '';
|
||||
my $source = '';
|
||||
my $locale = 'C';
|
||||
my $help_option = '--help';
|
||||
my $version_option = '--version';
|
||||
my ($opt_name, @opt_include, $opt_output, $opt_info, $opt_no_info);
|
||||
|
||||
my %opt_def = (
|
||||
'n|name=s' => \$opt_name,
|
||||
's|section=s' => \$section,
|
||||
'm|manual=s' => \$manual,
|
||||
'S|source=s' => \$source,
|
||||
'L|locale=s' => \$locale,
|
||||
'i|include=s' => sub { push @opt_include, [ pop, 1 ] },
|
||||
'I|opt-include=s' => sub { push @opt_include, [ pop, 0 ] },
|
||||
'o|output=s' => \$opt_output,
|
||||
'p|info-page=s' => \$opt_info,
|
||||
'N|no-info' => \$opt_no_info,
|
||||
'h|help-option=s' => \$help_option,
|
||||
'v|version-option=s' => \$version_option,
|
||||
);
|
||||
|
||||
# Parse options.
|
||||
Getopt::Long::config('bundling');
|
||||
GetOptions (%opt_def,
|
||||
help => sub { print $help_info; exit },
|
||||
version => sub { print $version_info; exit },
|
||||
) or die $help_info;
|
||||
|
||||
die $help_info unless @ARGV == 1;
|
||||
|
||||
die "$this_program: no locale support (Locale::gettext required)\n"
|
||||
unless $locale eq 'C' or $have_gettext;
|
||||
|
||||
# Set localisation of date and executable's ouput.
|
||||
delete @ENV{qw(LANGUAGE LC_MESSAGES LANG)};
|
||||
setlocale LC_ALL, $ENV{LC_ALL} = $locale;
|
||||
|
||||
my %include = ();
|
||||
my %append = ();
|
||||
my @include = (); # retain order given in include file
|
||||
|
||||
# Process include file (if given). Format is:
|
||||
#
|
||||
# [section name]
|
||||
# verbatim text
|
||||
#
|
||||
# or
|
||||
#
|
||||
# /pattern/
|
||||
# verbatim text
|
||||
#
|
||||
|
||||
while (@opt_include)
|
||||
{
|
||||
my ($inc, $required) = @{shift @opt_include};
|
||||
|
||||
next unless -f $inc or $required;
|
||||
kark N_("%s: can't open `%s' (%s)"), $this_program, $inc, $!
|
||||
unless open INC, $inc;
|
||||
|
||||
my $key;
|
||||
my $hash = \%include;
|
||||
|
||||
while (<INC>)
|
||||
{
|
||||
# [section]
|
||||
if (/^\[([^]]+)\]/)
|
||||
{
|
||||
$key = uc $1;
|
||||
$key =~ s/^\s+//;
|
||||
$key =~ s/\s+$//;
|
||||
$hash = \%include;
|
||||
push @include, $key unless $include{$key};
|
||||
next;
|
||||
}
|
||||
|
||||
# /pattern/
|
||||
if (m!^/(.*)/([ims]*)!)
|
||||
{
|
||||
my $pat = $2 ? "(?$2)$1" : $1;
|
||||
|
||||
# Check pattern.
|
||||
eval { $key = qr($pat) };
|
||||
if ($@)
|
||||
{
|
||||
$@ =~ s/ at .*? line \d.*//;
|
||||
die "$inc:$.:$@";
|
||||
}
|
||||
|
||||
$hash = \%append;
|
||||
next;
|
||||
}
|
||||
|
||||
# Check for options before the first section--anything else is
|
||||
# silently ignored, allowing the first for comments and
|
||||
# revision info.
|
||||
unless ($key)
|
||||
{
|
||||
# handle options
|
||||
if (/^-/)
|
||||
{
|
||||
local @ARGV = split;
|
||||
GetOptions %opt_def;
|
||||
}
|
||||
|
||||
next;
|
||||
}
|
||||
|
||||
$hash->{$key} ||= '';
|
||||
$hash->{$key} .= $_;
|
||||
}
|
||||
|
||||
close INC;
|
||||
|
||||
kark N_("%s: no valid information found in `%s'"), $this_program, $inc
|
||||
unless $key;
|
||||
}
|
||||
|
||||
# Compress trailing blank lines.
|
||||
for my $hash (\(%include, %append))
|
||||
{
|
||||
for (keys %$hash) { $hash->{$_} =~ s/\n+$/\n/ }
|
||||
}
|
||||
|
||||
# Grab help and version info from executable.
|
||||
my ($help_text, $version_text) = map {
|
||||
join '', map { s/ +$//; expand $_ } `$ARGV[0] $_ 2>/dev/null`
|
||||
or kark N_("%s: can't get `%s' info from %s"), $this_program,
|
||||
$_, $ARGV[0]
|
||||
} $help_option, $version_option;
|
||||
|
||||
my $date = strftime "%B %Y", localtime;
|
||||
(my $program = $ARGV[0]) =~ s!.*/!!;
|
||||
my $package = $program;
|
||||
my $version;
|
||||
|
||||
if ($opt_output)
|
||||
{
|
||||
unlink $opt_output or kark N_("%s: can't unlink %s (%s)"),
|
||||
$this_program, $opt_output, $! if -e $opt_output;
|
||||
|
||||
open STDOUT, ">$opt_output"
|
||||
or kark N_("%s: can't create %s (%s)"), $this_program, $opt_output, $!;
|
||||
}
|
||||
|
||||
# The first line of the --version information is assumed to be in one
|
||||
# of the following formats:
|
||||
#
|
||||
# <version>
|
||||
# <program> <version>
|
||||
# {GNU,Free} <program> <version>
|
||||
# <program> ({GNU,Free} <package>) <version>
|
||||
# <program> - {GNU,Free} <package> <version>
|
||||
#
|
||||
# and seperated from any copyright/author details by a blank line.
|
||||
|
||||
($_, $version_text) = split /\n+/, $version_text, 2;
|
||||
|
||||
if (/^(\S+) +\(((?:GNU|Free) +[^)]+)\) +(.*)/ or
|
||||
/^(\S+) +- *((?:GNU|Free) +\S+) +(.*)/)
|
||||
{
|
||||
$program = $1;
|
||||
$package = $2;
|
||||
$version = $3;
|
||||
}
|
||||
elsif (/^((?:GNU|Free) +)?(\S+) +(.*)/)
|
||||
{
|
||||
$program = $2;
|
||||
$package = $1 ? "$1$2" : $2;
|
||||
$version = $3;
|
||||
}
|
||||
else
|
||||
{
|
||||
$version = $_;
|
||||
}
|
||||
|
||||
$program =~ s!.*/!!;
|
||||
|
||||
# No info for `info' itself.
|
||||
$opt_no_info = 1 if $program eq 'info';
|
||||
|
||||
for ($include{_('NAME')})
|
||||
{
|
||||
if ($opt_name) # --name overrides --include contents.
|
||||
{
|
||||
$_ = "$program \\- $opt_name\n";
|
||||
}
|
||||
elsif ($_) # Use first name given as $program
|
||||
{
|
||||
$program = $1 if /^([^\s,]+)(?:,?\s*[^\s,\\-]+)*\s+\\?-/;
|
||||
}
|
||||
else # Set a default (useless) NAME paragraph.
|
||||
{
|
||||
$_ = sprintf _("%s \\- manual page for %s %s") . "\n", $program,
|
||||
$program, $version;
|
||||
}
|
||||
}
|
||||
|
||||
# Man pages traditionally have the page title in caps.
|
||||
my $PROGRAM = uc $program;
|
||||
|
||||
# Set default page head/footers
|
||||
$source ||= "$program $version";
|
||||
unless ($manual)
|
||||
{
|
||||
for ($section)
|
||||
{
|
||||
if (/^(1[Mm]|8)/) { $manual = _('System Administration Utilities') }
|
||||
elsif (/^6/) { $manual = _('Games') }
|
||||
else { $manual = _('User Commands') }
|
||||
}
|
||||
}
|
||||
|
||||
# Extract usage clause(s) [if any] for SYNOPSIS.
|
||||
my $PAT_USAGE = _('Usage');
|
||||
my $PAT_USAGE_CONT = _('or');
|
||||
if ($help_text =~ s/^($PAT_USAGE):( +(\S+))(.*)((?:\n(?: {6}\1| *($PAT_USAGE_CONT): +\S).*)*)//om)
|
||||
{
|
||||
my @syn = $3 . $4;
|
||||
|
||||
if ($_ = $5)
|
||||
{
|
||||
s/^\n//;
|
||||
for (split /\n/) { s/^ *(($PAT_USAGE_CONT): +)?//o; push @syn, $_ }
|
||||
}
|
||||
|
||||
my $synopsis = '';
|
||||
for (@syn)
|
||||
{
|
||||
$synopsis .= ".br\n" if $synopsis;
|
||||
s!^\S*/!!;
|
||||
s/^(\S+) *//;
|
||||
$synopsis .= ".B $1\n";
|
||||
s/\s+$//;
|
||||
s/(([][]|\.\.+)+)/\\fR$1\\fI/g;
|
||||
s/^/\\fI/ unless s/^\\fR//;
|
||||
$_ .= '\fR';
|
||||
s/(\\fI)( *)/$2$1/g;
|
||||
s/\\fI\\fR//g;
|
||||
s/^\\fR//;
|
||||
s/\\fI$//;
|
||||
s/^\./\\&./;
|
||||
|
||||
$synopsis .= "$_\n";
|
||||
}
|
||||
|
||||
$include{_('SYNOPSIS')} ||= $synopsis;
|
||||
}
|
||||
|
||||
# Process text, initial section is DESCRIPTION.
|
||||
my $sect = _('DESCRIPTION');
|
||||
$_ = "$help_text\n\n$version_text";
|
||||
|
||||
# Normalise paragraph breaks.
|
||||
s/^\n+//;
|
||||
s/\n*$/\n/;
|
||||
s/\n\n+/\n\n/g;
|
||||
|
||||
# Join hyphenated lines.
|
||||
s/([A-Za-z])-\n *([A-Za-z])/$1$2/g;
|
||||
|
||||
# Temporarily exchange leading dots, apostrophes and backslashes for
|
||||
# tokens.
|
||||
s/^\./\x80/mg;
|
||||
s/^'/\x81/mg;
|
||||
s/\\/\x82/g;
|
||||
|
||||
my $PAT_BUGS = _('Report +bugs|Email +bug +reports +to');
|
||||
my $PAT_AUTHOR = _('Written +by');
|
||||
my $PAT_OPTIONS = _('Options');
|
||||
my $PAT_EXAMPLES = _('Examples');
|
||||
my $PAT_FREE_SOFTWARE = _('This +is +free +software');
|
||||
|
||||
# Start a new paragraph (if required) for these.
|
||||
s/([^\n])\n($PAT_BUGS|$PAT_AUTHOR)/$1\n\n$2/og;
|
||||
|
||||
sub convert_option;
|
||||
|
||||
while (length)
|
||||
{
|
||||
# Convert some standard paragraph names.
|
||||
if (s/^($PAT_OPTIONS): *\n//o)
|
||||
{
|
||||
$sect = _('OPTIONS');
|
||||
next;
|
||||
}
|
||||
elsif (s/^($PAT_EXAMPLES): *\n//o)
|
||||
{
|
||||
$sect = _('EXAMPLES');
|
||||
next;
|
||||
}
|
||||
|
||||
# Copyright section
|
||||
if (/^Copyright +[(\xa9]/)
|
||||
{
|
||||
$sect = _('COPYRIGHT');
|
||||
$include{$sect} ||= '';
|
||||
$include{$sect} .= ".PP\n" if $include{$sect};
|
||||
|
||||
my $copy;
|
||||
($copy, $_) = split /\n\n/, $_, 2;
|
||||
|
||||
for ($copy)
|
||||
{
|
||||
# Add back newline
|
||||
s/\n*$/\n/;
|
||||
|
||||
# Convert iso9959-1 copyright symbol or (c) to nroff
|
||||
# character.
|
||||
s/^Copyright +(?:\xa9|\([Cc]\))/Copyright \\(co/mg;
|
||||
|
||||
# Insert line breaks before additional copyright messages
|
||||
# and the disclaimer.
|
||||
s/(.)\n(Copyright |$PAT_FREE_SOFTWARE)/$1\n.br\n$2/og;
|
||||
}
|
||||
|
||||
$include{$sect} .= $copy;
|
||||
$_ ||= '';
|
||||
next;
|
||||
}
|
||||
|
||||
# Catch bug report text.
|
||||
if (/^($PAT_BUGS) /o)
|
||||
{
|
||||
$sect = _('REPORTING BUGS');
|
||||
}
|
||||
|
||||
# Author section.
|
||||
elsif (/^($PAT_AUTHOR)/o)
|
||||
{
|
||||
$sect = _('AUTHOR');
|
||||
}
|
||||
|
||||
# Examples, indicated by an indented leading $, % or > are
|
||||
# rendered in a constant width font.
|
||||
if (/^( +)([\$\%>] )\S/)
|
||||
{
|
||||
my $indent = $1;
|
||||
my $prefix = $2;
|
||||
my $break = '.IP';
|
||||
$include{$sect} ||= '';
|
||||
while (s/^$indent\Q$prefix\E(\S.*)\n*//)
|
||||
{
|
||||
$include{$sect} .= "$break\n\\f(CW$prefix$1\\fR\n";
|
||||
$break = '.br';
|
||||
}
|
||||
|
||||
next;
|
||||
}
|
||||
|
||||
my $matched = '';
|
||||
$include{$sect} ||= '';
|
||||
|
||||
# Sub-sections have a trailing colon and the second line indented.
|
||||
if (s/^(\S.*:) *\n / /)
|
||||
{
|
||||
$matched .= $& if %append;
|
||||
$include{$sect} .= qq(.SS "$1"\n);
|
||||
}
|
||||
|
||||
my $indent = 0;
|
||||
my $content = '';
|
||||
|
||||
# Option with description.
|
||||
if (s/^( {1,10}([+-]\S.*?))(?:( +(?!-))|\n( {20,}))(\S.*)\n//)
|
||||
{
|
||||
$matched .= $& if %append;
|
||||
$indent = length ($4 || "$1$3");
|
||||
$content = ".TP\n\x84$2\n\x84$5\n";
|
||||
unless ($4)
|
||||
{
|
||||
# Indent may be different on second line.
|
||||
$indent = length $& if /^ {20,}/;
|
||||
}
|
||||
}
|
||||
|
||||
# Option without description.
|
||||
elsif (s/^ {1,10}([+-]\S.*)\n//)
|
||||
{
|
||||
$matched .= $& if %append;
|
||||
$content = ".HP\n\x84$1\n";
|
||||
$indent = 80; # not continued
|
||||
}
|
||||
|
||||
# Indented paragraph with tag.
|
||||
elsif (s/^( +(\S.*?) +)(\S.*)\n//)
|
||||
{
|
||||
$matched .= $& if %append;
|
||||
$indent = length $1;
|
||||
$content = ".TP\n\x84$2\n\x84$3\n";
|
||||
}
|
||||
|
||||
# Indented paragraph.
|
||||
elsif (s/^( +)(\S.*)\n//)
|
||||
{
|
||||
$matched .= $& if %append;
|
||||
$indent = length $1;
|
||||
$content = ".IP\n\x84$2\n";
|
||||
}
|
||||
|
||||
# Left justified paragraph.
|
||||
else
|
||||
{
|
||||
s/(.*)\n//;
|
||||
$matched .= $& if %append;
|
||||
$content = ".PP\n" if $include{$sect};
|
||||
$content .= "$1\n";
|
||||
}
|
||||
|
||||
# Append continuations.
|
||||
while ($indent ? s/^ {$indent}(\S.*)\n// : s/^(\S.*)\n//)
|
||||
{
|
||||
$matched .= $& if %append;
|
||||
$content .= "\x84$1\n"
|
||||
}
|
||||
|
||||
# Move to next paragraph.
|
||||
s/^\n+//;
|
||||
|
||||
for ($content)
|
||||
{
|
||||
# Leading dot and apostrophe protection.
|
||||
s/\x84\./\x80/g;
|
||||
s/\x84'/\x81/g;
|
||||
s/\x84//g;
|
||||
|
||||
# Convert options.
|
||||
s/(^| |\()(-[][\w=-]+)/$1 . convert_option $2/mge;
|
||||
|
||||
# Escape remaining hyphens
|
||||
s/-/\x83/g;
|
||||
}
|
||||
|
||||
# Check if matched paragraph contains /pat/.
|
||||
if (%append)
|
||||
{
|
||||
for my $pat (keys %append)
|
||||
{
|
||||
if ($matched =~ $pat)
|
||||
{
|
||||
$content .= ".PP\n" unless $append{$pat} =~ /^\./;
|
||||
$content .= $append{$pat};
|
||||
}
|
||||
}
|
||||
}
|
||||
|
||||
$include{$sect} .= $content;
|
||||
}
|
||||
|
||||
# Refer to the real documentation.
|
||||
unless ($opt_no_info)
|
||||
{
|
||||
my $info_page = $opt_info || $program;
|
||||
|
||||
$sect = _('SEE ALSO');
|
||||
$include{$sect} ||= '';
|
||||
$include{$sect} .= ".PP\n" if $include{$sect};
|
||||
$include{$sect} .= sprintf _(<<'EOT'), $program, $program, $info_page;
|
||||
The full documentation for
|
||||
.B %s
|
||||
is maintained as a Texinfo manual. If the
|
||||
.B info
|
||||
and
|
||||
.B %s
|
||||
programs are properly installed at your site, the command
|
||||
.IP
|
||||
.B info %s
|
||||
.PP
|
||||
should give you access to the complete manual.
|
||||
EOT
|
||||
}
|
||||
|
||||
# Output header.
|
||||
print <<EOT;
|
||||
.\\" DO NOT MODIFY THIS FILE! It was generated by $this_program $this_version.
|
||||
.TH $PROGRAM "$section" "$date" "$source" "$manual"
|
||||
EOT
|
||||
|
||||
# Section ordering.
|
||||
my @pre = (_('NAME'), _('SYNOPSIS'), _('DESCRIPTION'), _('OPTIONS'),
|
||||
_('EXAMPLES'));
|
||||
|
||||
my @post = (_('AUTHOR'), _('REPORTING BUGS'), _('COPYRIGHT'), _('SEE ALSO'));
|
||||
my $filter = join '|', @pre, @post;
|
||||
|
||||
# Output content.
|
||||
for my $sect (@pre, (grep ! /^($filter)$/o, @include), @post)
|
||||
{
|
||||
if ($include{$sect})
|
||||
{
|
||||
my $lsect = gettext $sect;
|
||||
my $quote = $lsect =~ /\W/ ? '"' : '';
|
||||
print ".SH $quote$lsect$quote\n";
|
||||
|
||||
for ($include{$sect})
|
||||
{
|
||||
# Replace leading dot, apostrophe, backslash and hyphen
|
||||
# tokens.
|
||||
s/\x80/\\&./g;
|
||||
s/\x81/\\&'/g;
|
||||
s/\x82/\\e/g;
|
||||
s/\x83/\\-/g;
|
||||
|
||||
# Convert some latin1 chars to troff equivalents
|
||||
s/\xa0/\\ /g; # non-breaking space
|
||||
|
||||
print;
|
||||
}
|
||||
}
|
||||
}
|
||||
|
||||
close STDOUT or kark N_("%s: error writing to %s (%s)"), $this_program,
|
||||
$opt_output || 'stdout', $!;
|
||||
|
||||
exit;
|
||||
|
||||
# Convert option dashes to \- to stop nroff from hyphenating 'em, and
|
||||
# embolden. Option arguments get italicised.
|
||||
sub convert_option
|
||||
{
|
||||
local $_ = '\fB' . shift;
|
||||
|
||||
s/-/\x83/g;
|
||||
unless (s/\[=(.*)\]$/\\fR[=\\fI$1\\fR]/)
|
||||
{
|
||||
s/=(.)/\\fR=\\fI$1/;
|
||||
s/ (.)/ \\fI$1/;
|
||||
$_ .= '\fR';
|
||||
}
|
||||
|
||||
$_;
|
||||
}
|
||||
|
|
@ -0,0 +1,60 @@
|
|||
.\" DO NOT MODIFY THIS FILE! It was generated by help2man 1.34.
|
||||
.TH KILL "1" "November 2004" "kill 5.3.0" "User Commands"
|
||||
.SH NAME
|
||||
kill \- send signals to processes, or list signals
|
||||
.SH SYNOPSIS
|
||||
.B kill
|
||||
[\fI-s SIGNAL | -SIGNAL\fR] \fIPID\fR...
|
||||
.br
|
||||
.B kill
|
||||
\fI-l \fR[\fISIGNAL\fR]...
|
||||
.br
|
||||
.B kill
|
||||
\fI-t \fR[\fISIGNAL\fR]...
|
||||
.SH DESCRIPTION
|
||||
.\" Add any additional description here
|
||||
.PP
|
||||
Send signals to processes, or list signals.
|
||||
.PP
|
||||
Mandatory arguments to long options are mandatory for short options too.
|
||||
.HP
|
||||
\fB\-s\fR, \fB\-\-signal\fR=\fISIGNAL\fR, \fB\-SIGNAL\fR
|
||||
.IP
|
||||
specify the name or number of the signal to be sent
|
||||
.TP
|
||||
\fB\-l\fR, \fB\-\-list\fR
|
||||
list signal names, or convert signal names to/from numbers
|
||||
.TP
|
||||
\fB\-t\fR, \fB\-\-table\fR
|
||||
print a table of signal information
|
||||
.TP
|
||||
\fB\-\-help\fR
|
||||
display this help and exit
|
||||
.TP
|
||||
\fB\-\-version\fR
|
||||
output version information and exit
|
||||
.PP
|
||||
SIGNAL may be a signal name like `HUP', or a signal number like `1',
|
||||
or an exit status of a process terminated by a signal.
|
||||
PID is an integer; if negative it identifies a process group.
|
||||
.SH AUTHOR
|
||||
Written by Paul Eggert.
|
||||
.SH "REPORTING BUGS"
|
||||
Report bugs to <bug\-coreutils@gnu.org>.
|
||||
.SH COPYRIGHT
|
||||
Copyright \(co 2004 Free Software Foundation, Inc.
|
||||
.br
|
||||
This is free software; see the source for copying conditions. There is NO
|
||||
warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
|
||||
.SH "SEE ALSO"
|
||||
The full documentation for
|
||||
.B kill
|
||||
is maintained as a Texinfo manual. If the
|
||||
.B info
|
||||
and
|
||||
.B kill
|
||||
programs are properly installed at your site, the command
|
||||
.IP
|
||||
.B info kill
|
||||
.PP
|
||||
should give you access to the complete manual.
|
||||
|
|
@ -0,0 +1,4 @@
|
|||
[NAME]
|
||||
kill \- send signals to processes, or list signals
|
||||
[DESCRIPTION]
|
||||
.\" Add any additional description here
|
||||
Loading…
Reference in New Issue