Separate bcopy and the copypage/zeropage stuff out of copy.s
so they can be used separately, and so the copyrights are attributed to the right owners. (Catch-all files are bad)
This commit is contained in:
parent
d531b1ed42
commit
521683f862
|
@ -0,0 +1,125 @@
|
|||
/* $NetBSD: bcopy.s,v 1.1 1997/03/17 19:44:33 gwr Exp $ */
|
||||
|
||||
/*-
|
||||
* Copyright (c) 1990 The Regents of the University of California.
|
||||
* All rights reserved.
|
||||
*
|
||||
* This code is derived from software contributed to Berkeley by
|
||||
* the Systems Programming Group of the University of Utah Computer
|
||||
* Science Department.
|
||||
*
|
||||
* Redistribution and use in source and binary forms, with or without
|
||||
* modification, are permitted provided that the following conditions
|
||||
* are met:
|
||||
* 1. Redistributions of source code must retain the above copyright
|
||||
* notice, this list of conditions and the following disclaimer.
|
||||
* 2. Redistributions in binary form must reproduce the above copyright
|
||||
* notice, this list of conditions and the following disclaimer in the
|
||||
* documentation and/or other materials provided with the distribution.
|
||||
* 3. All advertising materials mentioning features or use of this software
|
||||
* must display the following acknowledgement:
|
||||
* This product includes software developed by the University of
|
||||
* California, Berkeley and its contributors.
|
||||
* 4. Neither the name of the University nor the names of its contributors
|
||||
* may be used to endorse or promote products derived from this software
|
||||
* without specific prior written permission.
|
||||
*
|
||||
* THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
|
||||
* ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
|
||||
* IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
|
||||
* ARE DISCLAIMED. IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
|
||||
* FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
|
||||
* DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
|
||||
* OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
|
||||
* HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
|
||||
* LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
|
||||
* OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
|
||||
* SUCH DAMAGE.
|
||||
*/
|
||||
|
||||
/*
|
||||
* This is based on: src/lib/libc/arch/m68k/string/bcopy.S
|
||||
* identified as: @(#)bcopy.s 5.1 (Berkeley) 5/12/90
|
||||
*/
|
||||
|
||||
#include <machine/asm.h>
|
||||
|
||||
.file "bcopy.s"
|
||||
.text
|
||||
|
||||
/*
|
||||
* {ov}bcopy(from, to, len)
|
||||
* memcpy(to, from, len)
|
||||
*
|
||||
* Works for counts up to 128K.
|
||||
*/
|
||||
ALTENTRY(memmove, _memcpy)
|
||||
ENTRY(memcpy)
|
||||
movl sp@(12),d0 | get count
|
||||
jeq Lbccpyexit | if zero, return
|
||||
movl sp@(8), a0 | src address
|
||||
movl sp@(4), a1 | dest address
|
||||
jra Lbcdocopy | jump into bcopy
|
||||
ALTENTRY(ovbcopy, _bcopy)
|
||||
ENTRY(bcopy)
|
||||
movl sp@(12),d0 | get count
|
||||
jeq Lbccpyexit | if zero, return
|
||||
movl sp@(4),a0 | src address
|
||||
movl sp@(8),a1 | dest address
|
||||
Lbcdocopy:
|
||||
cmpl a1,a0 | src before dest?
|
||||
jlt Lbccpyback | yes, copy backwards (avoids overlap)
|
||||
movl a0,d1
|
||||
btst #0,d1 | src address odd?
|
||||
jeq Lbccfeven | no, go check dest
|
||||
movb a0@+,a1@+ | yes, copy a byte
|
||||
subql #1,d0 | update count
|
||||
jeq Lbccpyexit | exit if done
|
||||
Lbccfeven:
|
||||
movl a1,d1
|
||||
btst #0,d1 | dest address odd?
|
||||
jne Lbccfbyte | yes, must copy by bytes
|
||||
movl d0,d1 | no, get count
|
||||
lsrl #2,d1 | convert to longwords
|
||||
jeq Lbccfbyte | no longwords, copy bytes
|
||||
subql #1,d1 | set up for dbf
|
||||
Lbccflloop:
|
||||
movl a0@+,a1@+ | copy longwords
|
||||
dbf d1,Lbccflloop | til done
|
||||
andl #3,d0 | get remaining count
|
||||
jeq Lbccpyexit | done if none
|
||||
Lbccfbyte:
|
||||
subql #1,d0 | set up for dbf
|
||||
Lbccfbloop:
|
||||
movb a0@+,a1@+ | copy bytes
|
||||
dbf d0,Lbccfbloop | til done
|
||||
Lbccpyexit:
|
||||
rts
|
||||
Lbccpyback:
|
||||
addl d0,a0 | add count to src
|
||||
addl d0,a1 | add count to dest
|
||||
movl a0,d1
|
||||
btst #0,d1 | src address odd?
|
||||
jeq Lbccbeven | no, go check dest
|
||||
movb a0@-,a1@- | yes, copy a byte
|
||||
subql #1,d0 | update count
|
||||
jeq Lbccpyexit | exit if done
|
||||
Lbccbeven:
|
||||
movl a1,d1
|
||||
btst #0,d1 | dest address odd?
|
||||
jne Lbccbbyte | yes, must copy by bytes
|
||||
movl d0,d1 | no, get count
|
||||
lsrl #2,d1 | convert to longwords
|
||||
jeq Lbccbbyte | no longwords, copy bytes
|
||||
subql #1,d1 | set up for dbf
|
||||
Lbccblloop:
|
||||
movl a0@-,a1@- | copy longwords
|
||||
dbf d1,Lbccblloop | til done
|
||||
andl #3,d0 | get remaining count
|
||||
jeq Lbccpyexit | done if none
|
||||
Lbccbbyte:
|
||||
subql #1,d0 | set up for dbf
|
||||
Lbccbbloop:
|
||||
movb a0@-,a1@- | copy bytes
|
||||
dbf d0,Lbccbbloop | til done
|
||||
rts
|
|
@ -0,0 +1,107 @@
|
|||
/* $NetBSD: copypage.s,v 1.1 1997/03/17 19:44:35 gwr Exp $ */
|
||||
|
||||
/*-
|
||||
* Copyright (c) 1997 The NetBSD Foundation, Inc.
|
||||
* All rights reserved.
|
||||
*
|
||||
* This code is derived from software contributed to The NetBSD Foundation
|
||||
* by J.T. Conklin
|
||||
*
|
||||
* Redistribution and use in source and binary forms, with or without
|
||||
* modification, are permitted provided that the following conditions
|
||||
* are met:
|
||||
* 1. Redistributions of source code must retain the above copyright
|
||||
* notice, this list of conditions and the following disclaimer.
|
||||
* 2. Redistributions in binary form must reproduce the above copyright
|
||||
* notice, this list of conditions and the following disclaimer in the
|
||||
* documentation and/or other materials provided with the distribution.
|
||||
* 3. All advertising materials mentioning features or use of this software
|
||||
* must display the following acknowledgement:
|
||||
* This product includes software developed by the NetBSD
|
||||
* Foundation, Inc. and its contributors.
|
||||
* 4. Neither the name of The NetBSD Foundation nor the names of its
|
||||
* contributors may be used to endorse or promote products derived
|
||||
* from this software without specific prior written permission.
|
||||
*
|
||||
* THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
|
||||
* ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
|
||||
* TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
|
||||
* PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
|
||||
* BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
|
||||
* CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
|
||||
* SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
|
||||
* INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
|
||||
* CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
|
||||
* ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
|
||||
* POSSIBILITY OF SUCH DAMAGE.
|
||||
*/
|
||||
|
||||
/*
|
||||
* Optimized functions for copying/clearing a whole page.
|
||||
*/
|
||||
|
||||
#include <machine/asm.h>
|
||||
#include "assym.h"
|
||||
|
||||
.file "copypage.s"
|
||||
.text
|
||||
|
||||
/*
|
||||
* copypage040(fromaddr, toaddr)
|
||||
*
|
||||
* Optimized version of bcopy for a single page-aligned NBPG byte copy,
|
||||
* using instuctions only available on the mc68040 and later.
|
||||
*/
|
||||
#if defined(M68040) || defined(M68060)
|
||||
ENTRY(copypage040)
|
||||
movl sp@(4),a0 | source address
|
||||
movl sp@(8),a1 | destiniation address
|
||||
movl #NBPG/32-1,d0 | number of 32 byte chunks - 1
|
||||
Lm16loop:
|
||||
.long 0xf6209000 | move16 a0@+,a1@+
|
||||
.long 0xf6209000 | move16 a0@+,a1@+
|
||||
dbf d0,Lm16loop
|
||||
rts
|
||||
#endif /* M68040 || M68060 */
|
||||
|
||||
/*
|
||||
* copypage(fromaddr, toaddr)
|
||||
*
|
||||
* Optimized version of bcopy for a single page-aligned NBPG byte copy.
|
||||
*/
|
||||
ENTRY(copypage)
|
||||
movl sp@(4),a0 | source address
|
||||
movl sp@(8),a1 | destiniation address
|
||||
movl #NBPG/32-1,d0 | number of 32 byte chunks - 1
|
||||
Lmlloop:
|
||||
movl a0@+,a1@+
|
||||
movl a0@+,a1@+
|
||||
movl a0@+,a1@+
|
||||
movl a0@+,a1@+
|
||||
movl a0@+,a1@+
|
||||
movl a0@+,a1@+
|
||||
movl a0@+,a1@+
|
||||
movl a0@+,a1@+
|
||||
dbf d0,Lmlloop
|
||||
rts
|
||||
|
||||
/*
|
||||
* zeropage(addr)
|
||||
*
|
||||
* Optimized version of bzero for a single page-aligned NBPG byte zero.
|
||||
*/
|
||||
ENTRY(zeropage)
|
||||
movl sp@(4),a0 | dest address
|
||||
movl #NBPG/32-1,d0 | number of 32 byte chunks - 1
|
||||
movq #0,d1
|
||||
Lzloop:
|
||||
movl d1,a0@+
|
||||
movl d1,a0@+
|
||||
movl d1,a0@+
|
||||
movl d1,a0@+
|
||||
movl d1,a0@+
|
||||
movl d1,a0@+
|
||||
movl d1,a0@+
|
||||
movl d1,a0@+
|
||||
dbf d0,Lzloop
|
||||
rts
|
Loading…
Reference in New Issue