From 3f38b4d7ad95162d65d0c36bf0b9cba1b3c6dbe7 Mon Sep 17 00:00:00 2001
From: cgd <cgd@NetBSD.org>
Date: Mon, 15 Jul 1996 03:13:41 +0000
Subject: [PATCH] add an assembly version of ffs(), copied down from libc

---
 sys/lib/libkern/arch/alpha/Makefile.inc |  4 +-
 sys/lib/libkern/arch/alpha/ffs.S        | 85 +++++++++++++++++++++++++
 2 files changed, 87 insertions(+), 2 deletions(-)
 create mode 100644 sys/lib/libkern/arch/alpha/ffs.S

diff --git a/sys/lib/libkern/arch/alpha/Makefile.inc b/sys/lib/libkern/arch/alpha/Makefile.inc
index 971480fda03c..962971e9dd92 100644
--- a/sys/lib/libkern/arch/alpha/Makefile.inc
+++ b/sys/lib/libkern/arch/alpha/Makefile.inc
@@ -1,7 +1,7 @@
-#	$NetBSD: Makefile.inc,v 1.6 1996/06/10 15:33:46 cgd Exp $
+#	$NetBSD: Makefile.inc,v 1.7 1996/07/15 03:13:41 cgd Exp $
 
 SRCS+=	__main.c imax.c imin.c lmax.c lmin.c max.c min.c ulmax.c ulmin.c \
-	bcmp.c bzero.S ffs.c strcat.c strcmp.c strcpy.c strlen.c strncmp.c \
+	bcmp.c bzero.S ffs.S strcat.c strcmp.c strcpy.c strlen.c strncmp.c \
 	strncpy.c scanc.c skpc.c htonl.S htons.S ntohl.S ntohs.S \
 	random.c strncasecmp.c
 
diff --git a/sys/lib/libkern/arch/alpha/ffs.S b/sys/lib/libkern/arch/alpha/ffs.S
new file mode 100644
index 000000000000..f182e5267e8a
--- /dev/null
+++ b/sys/lib/libkern/arch/alpha/ffs.S
@@ -0,0 +1,85 @@
+/*	$NetBSD: ffs.S,v 1.1 1996/07/15 03:13:42 cgd Exp $	*/
+
+/*
+ * Copyright (c) 1995 Christopher G. Demetriou
+ * All rights reserved.
+ *
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions
+ * are met:
+ * 1. Redistributions of source code must retain the above copyright
+ *    notice, this list of conditions and the following disclaimer.
+ * 2. Redistributions in binary form must reproduce the above copyright
+ *    notice, this list of conditions and the following disclaimer in the
+ *    documentation and/or other materials provided with the distribution.
+ * 3. All advertising materials mentioning features or use of this software
+ *    must display the following acknowledgement:
+ *      This product includes software developed by Christopher G. Demetriou
+ *	for the NetBSD Project.
+ * 4. The name of the author may not be used to endorse or promote products
+ *    derived from this software without specific prior written permission
+ *
+ * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
+ * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
+ * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
+ * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
+ * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
+ * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+ * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+ * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+ * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
+ * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+ */
+
+#include "DEFS.h"
+
+LEAF(ffs, 1)
+	addl	a0, 0, a0
+	beq	a0, Lallzero
+
+	ldil	v0, 1
+
+	and	a0, 0xff, t0
+	bne	t0, Ldo8
+
+	/*
+	 * If lower 16 bits empty, add 16 to result and use upper 16.
+	 */
+	zapnot	a0, 0x03, t1
+	bne	t1, Ldo16
+	sra	a0, 16, a0
+	addl	v0, 16, v0
+
+Ldo16:
+	/*
+	 * If lower 8 bits empty, add 8 to result and use upper 8.
+	 */
+	and	a0, 0xff, t2
+	bne	t2, Ldo8
+	sra	a0, 8, a0
+	addl	v0, 8, v0
+
+Ldo8:
+	and	a0, 0x0f, t3		/* lower 4 of 8 empty? */
+	and	a0, 0x33, t4		/* lower 2 of each 4 empty? */
+	and	a0, 0x55, t5		/* lower 1 of each 2 empty? */
+
+	/* If lower 4 bits empty, add 4 to result. */
+	bne	t3, Ldo4
+	addl	v0, 4, v0
+
+Ldo4:	/* If lower 2 bits of each 4 empty, add 2 to result. */
+	bne	t4, Ldo2
+	addl	v0, 2, v0
+
+Ldo2:	/* If lower bit of each 2 empty, add 1 to result. */
+	bne	t5, Ldone
+	addl	v0, 1, v0
+
+Ldone:
+	RET
+
+Lallzero:
+	bis	zero, zero, v0
+	RET
+END(ffs)